Анимация на аssembler

[bvak]

Нужна помощь по созданию анимации танцующего человечка. Я нашел здесь на сайте программу, но никак не мог понять как прилепить 3 кадр или больше.

code segment
        ASSUME CS:code, DS:DATA_SEG, ES:NOTHING, SS:STACK_SEG
start:
        MOV     AX,DATA_SEG
        MOV     DS,AX
        MOV     AX,STACK_SEG
        MOV     SS,AX
        MOV     SP, OFFSET TOP_OF_STACK
        

        MOV     AX,13h
        INT     10h

        MOV     AX,0A000h 
        MOV     ES,AX 
        CLD

        MOV     DI,320*12

        MOV     BH, 48
       

MOVE_MASK:
        MOV     AL, NOM_KADR
        CMP     AL,0
        JNZ     KADR2
        MOV     NOM_KADR, 1
        MOV     SI, OFFSET H1
        JMP     SHOW_KADR
KADR2:
        MOV     NOM_KADR, 0
        MOV     SI, OFFSET H2

SHOW_KADR:
        PUSH    DI        
        MOV     BL,13    


DRAW_H:
        MOV     CX,12     
        REP     MOVSB
        ADD     DI,320-12 
        DEC     BL
        JNZ     DRAW_H
        POP     DI        
        INC     DI        

READ_KEY:
        MOV     AH,08h
        INT     21h
        cmp     al,0 ; Проверка на расш.коды
        JZ      READ_KEY
        cmp     al, 'q'
        JNZ     MOVE_MASK

        MOV     AX,3
        INT     10h                 

        MOV     AH,4Ch
        INT     21h



DATA_SEG SEGMENT

H1 DB 0,0,0,0,0,9,9,9,9,0,0,0
      DB 0,0,0,0,0,9,9,9,9,0,0,0
      DB 0,0,0,0,0,9,9,0,0,0,0,0
      DB 0,0,0,9,9,9,9,9,9,0,0,0
      DB 0,0,0,9,9,9,9,9,9,0,0,0
      DB 0,9,9,0,0,9,9,0,0,9,9,0
      DB 0,9,9,0,0,9,9,0,0,9,9,0
      DB 0,0,0,0,0,9,9,0,0,0,0,0
      DB 0,0,0,0,0,9,9,0,0,0,0,0
      DB 0,0,0,9,9,0,0,9,9,0,0,0
      DB 0,0,0,9,9,0,0,9,9,0,0,0
      DB 0,9,9,0,0,0,0,0,0,9,9,0
      DB 0,9,9,0,0,0,0,0,0,9,9,0
     
H2     DB 0,0,0,0,0,9,9,9,9,0,0,0
       DB 0,0,0,0,0,9,9,9,9,0,0,0
       DB 0,0,0,0,0,9,9,0,0,0,0,0
       DB 0,0,0,9,9,9,9,9,9,0,0,0
       DB 0,0,0,9,9,9,9,9,9,0,0,0
       DB 0,9,9,0,0,9,9,0,0,9,9,0
       DB 0,9,9,0,0,9,9,0,0,9,9,0
       DB 0,0,0,0,0,9,9,0,0,0,0,0
       DB 0,0,0,0,0,9,9,9,9,0,0,0
       DB 0,0,0,9,9,0,0,9,9,0,0,0
       DB 0,0,0,9,9,0,0,9,9,0,0,0
       DB 0,9,9,0,0,0,0,9,9,0,0,0
       DB 0,9,9,0,0,0,0,0,0,0,0,0
NOM_KADR DB 0
DATA_SEG ENDS

STACK_SEG SEGMENT
        DB 64 DUP('STACK')
TOP_OF_STACK DW ?
STACK_SEG ENDS

code ends
end start
end

[Serge_Bliznykov]

элементарно...
программа написана весьма кузявно, поэтому с добавлением 3-го (а так же 4-го, 5-го и т.д. кадра) проблем вообще не будет!

посмотрите,
по метке MOVE_MASK:
находится код, который по значению переменной NOM_KADR
определяет, какую маску(кадр) использовать.
в данный момент доступны кадры H1 и H2
добавляйте в область данных ещё H3 (рисунок 3-го кадра)
и подправьте процедуру по метке MOVE_MASK, так,
чтобы грузился третий кадр: MOV SI, OFFSET H3
и всё. задача решена!

[bvak]

Все сделал как вы сказали. Не понимаю. Вроде должна работать. Но показывает только 3й кадр

MOVE_MASK:
MOV AL, NOM_KADR
CMP AL,0
JNZ KADR2
MOV AL, NOM_KADR
CMP AL,2
JNZ KADR3

MOV NOM_KADR, 1
MOV SI, OFFSET H1
JMP SHOW_KADR

KADR2:
MOV NOM_KADR, 0
MOV SI, OFFSET H2
KADR3:
MOV NOM_KADR, 2
MOV SI, OFFSET H3

[Serge_Bliznykov]

а попробуйте такой код:

MOVE_MASK:
        MOV     AL, NOM_KADR
        CMP     AL, 0
        JNZ     KADR2
        MOV     NOM_KADR, 1
        MOV     SI, OFFSET H1
        JMP     SHOW_KADR
KADR2:
        CMP     AL, 1
        JNZ     KADR3
        MOV     NOM_KADR, 2
        MOV     SI, OFFSET H2
        JMP     SHOW_KADR

KADR3:
        MOV     NOM_KADR, 0
        MOV     SI, OFFSET H3

SHOW_KADR:

[bvak]

спасибо большое. все заработало.