Печать цветных и черно-белых страниц на разные принтеры

[rain_day]

Я в отчаянии
Постоянно приходится печатать документы большого объёма со страницами с изображениями (графики (внедренные объекты экселя), рисунки (jpg, tif, и др)) на цветном принтере, черно-белые страницы на обычном лазерном принтере - существует ли какая-нибудь возможность это сделать автоматически, а не выбирать страницы и вручную вбивать номера? Документы как правило около 150 стр. а цветные около 50 стр.

[viter.alex]

Единственное, что могу предложить, то это проверить все страницы на наличие в них изображений. По результатам проверки сформировать два набора номеров страниц: страницы, содержащие изображения и без таковых. Ну а затем оправить на печать на разные принтеры

[rain_day]

А как сделать такую проверку?

[viter.alex]

Попробуй так, не проверял. Задай константам имена своих принтеров.

Sub SeparatePrint()
  Const PRINTER_BW = "Принтер чернобелой печати"
  Const PRINTER_COLOR = "Принтер цветной печати"
  Dim sBWPages As String 'Строка для номеров страниц на ч\б печать
  Dim sColorPages As String 'Строка для номеров страниц на цветную печать
  Dim oDoc As Document: Set oDoc = ActiveDocument 'Документ, который нужно распечатать
  Dim nPage As Long: nPage = 1 'Номер страницы
  Dim oPageRng As Range 'Диапазон отдельной страницы
  Dim nPages As Long: nPages = oDoc.Range.ComputeStatistics(wdStatisticPages) 'Количество страниц в документе
  Do
    'Переходим в начало отдельной страницы
    Set oPageRng = oDoc.Range.GoTo(wdGoToPage, wdGoToAbsolute, nPage)
    'Растягиваем диапазон на всю страницу
    If nPage < nPages Then
      oPageRng.SetRange oPageRng.Start, oDoc.Range.GoTo(wdGoToPage, wdGoToAbsolute, nPage + 1).Start
    Else
      oPageRng.SetRange oPageRng.Start, oDoc.Range.End
    End If
    
    If oPageRng.InlineShapes.Count = 0 And oPageRng.ShapeRange.Count = 0 Then 'Если нет рисунков
      sBWPages = sBWPages & nPage & "," 'Добавляем в список страниц для печати на ч\б принтер
    Else 'Если есть рисунки
      sColorPages = sColorPages & nPage & "," 'Добавляем в список страниц для печати на цветной принтер
    End If
    nPage = nPage + 1
  Loop While nPage <= nPages
  sBWPages = Left(sBWPages, Len(sBWPages) - 1)
  sColorPages = Left(sColorPages, Len(sColorPages) - 1)
  ActivePrinter = PRINTER_BW 'Задаем ч\б принтер
  'Отправляем на печать ч\б страницы
  oDoc.PrintOut Range:=wdPrintRangeOfPages, Pages:=sBWPages
  ActivePrinter = PRINTER_COLOR 'Задаем цветной принтер
  'Отправляем на печать цветные страницы
  oDoc.PrintOut Range:=wdPrintRangeOfPages, Pages:=sBWPages
End Sub

[rain_day]

Спасибо Вам за уделяемое внимание. Но куда этот код тепрь? Этот код надо вставить в новый макрос?

[viter.alex]

Код немного изменил: перенес объявления констант внутрь процедуры. Весь этот код и является макросом. Вставляете его туда, где у вас все макросы, и запускаете.

[rain_day]

Да да, вот уже тестирую. Внутрь процедуры это куда?

[viter.alex]

Сообщение от rain_day

Да да, вот уже тестирую. Внутрь процедуры это куда?

Как это куда? В первом варианте константы, задающие имена принтеров, были заданы вне процедуры.

Const PRINTER_BW = "Принтер чернобелой печати"
Const PRINTER_COLOR = "Принтер цветной печати"
Sub SeparatePrint()
…
End Sub

Теперь они находятся внутри процедуры:

Sub SeparatePrint()
  Const PRINTER_BW = "Принтер чернобелой печати"
  Const PRINTER_COLOR = "Принтер цветной печати"
…
End Sub

Разница в том, что в первом варианте эти константы могут использовать все процедуры в проекте, а во втором, только та, в которой они объявлены.

[rain_day]

В первом варианте результаты неоднозначные. Чб принтер действительно выдал чб страницы. А цв принтер начал печатать всё подряд с первой страницы и я отключил его. Во втором варианте ни чего не изменилось

[viter.alex]

Сообщение от rain_day

В первом варианте результаты неоднозначные. Чб принтер действительно выдал чб страницы. А цв принтер начал печатать всё подряд с первой страницы и я отключил его. Во втором варианте ни чего не изменилось

Вот и хорошо! Значит, принцип правильный. Думаю дело в том, что мы меняем активный принтер, когда задание на печать еще не выполнено. Вот и сбоит. Будем думать.