Вывод сообщения о скрытом тексте

[Busine2009]

Как написать макрос, который бы при открытии документа выводил сообщение, что в документе содержится скрытый текст?

Здесь есть один (а может и больше - не знаю) нюанс: если в документе содержится больше 50 абзацев, то ворд видит скрытый текст.

[CaptainNemo]

По-моему вопросы скрытого текста обсуждались на форуме уже неоднократно. Но если сделать скидку на то, что повторенье – мать ученья, то можно и повторить…
Самый простой путь написать - это воспользоваться макрорекодером. А для того, что бы этот макрос запускался при открытии документа, нужно ещё осознать концепцию событий Office.
Что касается скрытого текста в целом, то проверить документ на наличие такового можно просмотрев все символы в цикле на свойство Hidden (поскольку и пробел может быть скрытым). Ну, например, вот так (это самый примитивный вариант кода, его нужно поместить в модуль ThisDocument):

Private Sub Document_Open()
With ActiveDocument
For i = 1 To .Characters.Count
    If .Characters(i).Font.Hidden = True Then
        MsgBox "Есть скрытый текст"
        Exit Sub
    End If
Next i
End With
End Sub

[viter.alex]

Действительно, ошибается Word при большом количестве абзацев. Тогда можно их просто перебрать. Это займет некоторое время, но результат будет точным

Sub ShowHidden()
  Dim bHid As Boolean, oPar As Paragraph
  For Each oPar In ActiveDocument.Paragraphs
    bHid = bHid Or oPar.Range.Font.Hidden
  Next
  If bHid Then MsgBox "В документе есть скрытый текст!"
End Sub

CaptainNemo, думаю, что проверять каждый символ нет необходимости.

[CaptainNemo]

А я думаю, что необходимость всё же есть. Ваш код не ищет скрытые непечатные знаки внутри параграфа. А иногда это может пригодится…

[Busine2009]

Спасибо за ответы, завтра гляну.

[Busine2009]

Использовал макрос Витера.

Уже 2 раз помог.

Хотя я свою систему разработал: это при открытии документов выводить диалоговое окно "Найти и заменить", чтобы не забывать проводить проверку на наличие скрытого текста. Но макрос, бессомненно, лучше.

Хотя я сей час подумал, макрос Витера не ищет скрытый текст в колонтитулах, а с помощью диалогового окна "Найти и заменить" скрытый текст ищется в колонтитулах, что может сыграть существенную роль, поэтому, наверное, надо перейти к своему способу поиска скрытого текста.

Или надо добавить в код что-то связанное с колонтитулами, их не много, поэтому, наверное, время мало займет на выполнения макроса, думаю, что сам смогу переделать этот код.

[Energy42]

Мой вопрос перекликается с вопросом, озвученным в этой теме, поэтому не стал заводить новый топик...

В документе есть скрытый текст, в котором "спрятано" ключевое слово, макрос должен найти это ключевое слово и на его месте вставить содержимое другого документа.
Делаю так:

Private Sub test()
With ActiveDocument.Content.Find
.Forward = True
.ClearFormatting
.MatchWholeWord = True
.MatchCase = False
.Wrap = wdFindContinue
If .Execute(FindText:="<$insdoc$>") = True Then
.Parent.Select
Selection.InsertFile FileName:="c:\...\insdoc.doc", ConfirmConversions:=False, Link:=True, Attachment:=False
End If
End With
End Sub

Этот код работает если ключевое слово не скрыто, если же сделать скрытым, то код не может найти скрытый текст и соответственно вставить документ.

Вопрос: Как выполнить поиск учитывая скрытый текст и найдя это место, вставить, заместо скрытого текста, содержимое другого документа?

[viter.alex]

Попробуйте так:

Sub FindHidden()
  Selection.HomeKey wdStory, wdMove
  With Selection.Find
    .ClearFormatting
    .Text = "<$insdoc$>"
    .Font.Hidden = True
    .MatchWholeWord = True
    .Format = True
    If .Execute Then Selection.InsertFile FileName:="c:\...\insdoc.doc", ConfirmConversions:=False, Link:=True, Attachment:=False
  End With
End Sub

[Energy42]

Такой код не работает, я тоже так пробовал...
Временно сделал такой вариант:

Private Sub test()
  Dim WasShowHiddenText
  WasShowHiddenText = ActiveDocument.ActiveWindow.View.ShowHiddenText
  ActiveDocument.ActiveWindow.View.ShowHiddenText = True
  With ActiveDocument.Content.Find
    .Forward = True
    .ClearFormatting
    .MatchWholeWord = True
    .MatchCase = False
    .Wrap = wdFindContinue
    If .Execute(FindText:="<$insdoc$>") = True Then
      .Parent.Select
      Selection.InsertFile FileName:="c:\...\insdoc.doc", ConfirmConversions:=False, Link:=True, Attachment:=False
    End If
  End With
  ActiveDocument.ActiveWindow.View.ShowHiddenText = WasShowHiddenText
End Sub

То есть перед поиском принудительно показываю скрытый текст, после поиска, возвращаю первоначальный режим просмотра. На небольших документах, не заметно "моргание", но если машина будет медленная, то наверняка будет видно.

Возможное найдётся более красивое решение?

[БуреВестник]

В начале кода вставляете

Application.ScreenUpdating = False

В конце кода вставляете.

Application.ScreenUpdating = True