Макрос на разделение одного столбца в два по условию

[Aleksey-ssx29]

Здравствуйте!
Пожалуйста, помогите составить макрос разделения одного стобца на два столбца - всё, что находится в ячейке до первой (!) найденной восьмерки (8) - оставляем в этой ячейке, а начиная с данной "8" - вырезаем в следующий столбец.

Пример:

Было "латкимщаь83739птвро8455"
Стало "латкимщаь" и "83739птвро8455"

Спасибо заранее за помощь!
Самому мне быстро не удалось понять как сделать - нубоват

[Aleksandr H.]

Sub Splitter()
    Dim r As Integer
    Dim rng As Range
    Dim p As Integer
    Dim v
    Set rng = ActiveCell
    r = Cells(Rows.Count, rng.Column).End(xlUp).Row
    Do While r >= 1
        v = Cells(r, rng.Column)
        p = InStr(v, "8")
        If p > 1 Then
            Cells(r, rng.Column) = Mid(v, 1, p - 1)
            Cells(r, rng.Column + 1) = Mid(v, p)
        End If
        r = r - 1
    Loop
End Sub

[svsh2016]

вариант функций в C1 и E1

Function vvv1$(t$)
 With CreateObject("VBScript.RegExp"): .Pattern = "^.+?(?=8)"
    vvv1 = .Execute(t)(0)
 End With
End Function

Function vvv2$(t$)
 With CreateObject("VBScript.RegExp"): .Pattern = "8.+$"
    vvv2 = .Execute(t)(0)
 End With
End Function

[svsh2016]

вариант с макросом,соответствующем вышеуказанным функциям
кнопки test и повтор на листе Лист2

Sub test()
     Dim z, z1, t$, i&: z = Range("A1:A" & Range("A" & Rows.Count).End(xlUp).Row).Value
     ReDim z1(1 To UBound(z), 1 To 2)
  With CreateObject("VBScript.RegExp")
    For i = 1 To UBound(z): t = z(i, 1)
  .Pattern = "^.+?(?=8)":   z1(i, 1) = .Execute(t)(0)
  .Pattern = "8.+$": z1(i, 2) = .Execute(t)(0)
   Next
   Range("A1").Resize(UBound(z1), 2).Value = z1
   End With
End Sub