Запрет вставки значений в ячейку из буфера обмена

[ольгаг]

Здравствуйте Уважаемые программисты!
Помогите пожалуйста возможно кодом сделать следующее:
на листе excel 2003 для ячейки A1 назначена проверка ввода только числовых значений (через данные - проверка - другой - =ечисло(A1)). Но проверка работает только при вводе значения в ячейку с клавиатуры, но если вставить из буфера обмена, то не работает.
Подскажите пожалуйста как можно запретить вставку в ячейку скопированного значения из буфера обмена?
Спасибо!

[IgorGO]

полагаю, что ни как

[ольгаг]

Нашла такой код:
в модуле листа:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim cell As Range
Dim bIsNumeric As Boolean
bIsNumeric = True
For Each cell In Range("A1:A10")
    If IsNumeric(cell) = False Then
        bIsNumeric = False
        Exit For
    End If
Next cell
If bIsNumeric = False Then
    cell.ClearContents
    MsgBox "Можно вводить только числа"
End If
End Sub

Код работает если вставить в ячейку из буфера обмена не число и кликнуть по другой ячейке. Подскажите пожалуйста, можно этот код изменить так, чтобы он срабатывал сразу после вставки?
Спасибо!

[Казанский]

Пробуйте, в случае ввода нечислового значения код вернет прежнее значение.

Private Sub Worksheet_Change(ByVal Target As Range)
  If Not Intersect(Target, Range("A1")) Is Nothing Then
    If VarType(Range("A1").Value2) <> vbDouble Then
      Application.EnableEvents = False
      Application.Undo
      Application.EnableEvents = True
      MsgBox "Можно вводить только числа"
    End If
  End If
End Sub

[ольгаг]

Спасибо большое!