как перевести диапазон значений в режим ПРОПИСНых букв без цикла?

[Aleksandr H.]

как перевести диапазон значений в режим ПРОПИСНых букв без цикла
Решение http://stackoverflow.com/questions/1...-all-the-cells
дает результат

#ИМЯ?

по всем ячейкам

Sub a()
Dim rng As Range
Set rng = Range("a18:a20")
rng = [index(upper(rng),)]
'rng = [index(upcase(rng),)]
'rng = [Application.Worksheetfunction.Index(Application.WorksheetFunction.upper(rng),)]
End Sub

[pashulka]

Если rng может меняться, то, как вариант :

rng = Evaluate("INDEX(UPPER(" & rng.Address(, , , True) & "),)")
'rng = rng.Worksheet.Evaluate("INDEX(UPPER(" & rng.Address & "),)")

[staniiislav]

можно только так:

Sub a()
Dim rng As Range
Set rng = Range("B6:B9")
rng = [index(upper(B6:B9),)]
End Sub

или так:

Sub a()
Range("B6:B9") = [index(upper(B6:B9),)]
End Sub

или так:

Sub a()
[B6:B9] = [index(upper(B6:B9),)]
End Sub

Дело в том, что значения в

[index(upper(B6:B9),)]

не передаются, vba считывает эти данные как строку, следовательно не какие переменные, значения и функции не получится вставить.

[staniiislav]

ну или как предложил pashulka

[pashulka]

Если очень хочется использовать []

Private Sub Test()
    Dim rng As Range
    Set rng = Range("A18:A20")
    rng.Name = "LowerToUpper"
    rng = [INDEX(UPPER(LowerToUpper),)]
    'Names("LowerToUpper").Delete
End Sub

[Казанский]

вот так будет работать с любым стилем ссылок - А1 или R1C1

Sub a()
  With Range("a18:a20")
    .Value = Evaluate("INDEX(UPPER(" & .Address(, , Application.ReferenceStyle) & "),)")
  End With
End Sub

[pashulka]

Вот так будет работать с любым рабочим листом - даже неактивным

Sub a2()
  With Worksheets("Лист3").Range("a18:a20")
    .Value = Evaluate("INDEX(UPPER(" & .Address(, , Application.ReferenceStyle, True) & "),)")
    '.Value = .Parent.Evaluate("INDEX(UPPER(" & .Address(, , Application.ReferenceStyle) & "),)")
  End With
End Sub