Поиск номера строки содержащего заданный текст в коде VBA проекта

[who]

Есть у меня такой код в проекте:

Sub udalcod()
b = "Private Sub CommandButton1_Click()"
 l = ThisWorkbook.VBProject.VBComponents("Лист01"). _
    CodeModule.Find(b, 1, 1, 1000, 150, False, False, False)
End Sub

результатом которого является "True" или "False", в зависимости от наличия совпадений.
Как мне получить номер строки с первым совпадением

[who]

Решил сам. Спасибо, если пытались помочь...

[Aleksandr H.]

Как решил? Может кому-то пригодится?

[pashulka]

Мне тоже интересно ... неужели нашёлся человек, который прочёл справку, где говорится, что четвёртый аргумент это, цитирую

Переменная типа Long, указывающая номер последней строки совпадающего с образцом текста (если он найден).

Private Sub Test()
    Dim iText$, iLine&
    iText = "Private Sub CommandButton1_Click()"
    
    If ThisWorkbook.VBProject.VBComponents("Лист01"). _
       CodeModule.Find(iText, 1, 1, iLine, 1) Then
       MsgBox "Искомый текст нашёлся в строке #" & iLine
    End If
End Sub

[who]

моё решение такое:

Sub udalcod(i)
Dim linedel As Long
lcount = ThisWorkbook.VBProject.VBComponents("Лист01").CodeModule.CountOfLines
b = "Private Sub CommandButtonI_" & i - 2 & "_Click()"
    For linedel = 1 To lcount
        findtext = ThisWorkbook.VBProject.VBComponents("Лист01").CodeModule.Find _
                   (b, linedel, 1, linedel, 1000, False, False, False)
        If findtext = True Then
            MsgBox linedel
            ThisWorkbook.VBProject.VBComponents("Лист01").CodeModule.DeleteLines linedel, 4
            Exit For
        End If
    Next linedel
End Sub

ну справку я прочесть не успел, а по всплываючей подсказке в редакторе предположил, что 4-й аргумент -- это номер последней строки поиска

find(Target As String, StartLine As long, StartColumn As long, EndLine As long, EndColumn As long, [WholeWord As Boolean], [MathCase As Boolean], [PatternSeach As Boolean]) As Boolean

и ещё я не совсем понимаю что значат символы & и $ в описаниях переменных, а точнее совсем не понимаю (я в VBA самоучка, программирование учил в универе только на Delphi, да и то не углублено... и применяю VBA по жизненной необходимости на работе для себя)

[pashulka]

Цитата из справки

Тип данных String. Символом описания типа для типа String служит символ доллара $

Тип данных Long. Символом описания типа для типа Long служит символ &

[who]

Спасибо, понятненько теперь...

[pashulka]

Who, Обратите внимание на то, что в своём решении Вы осуществляете поиск построчно, что можно осуществить и без метода .Find

Private Sub FindCodeInLine()
    Dim iText$, iCount&
    
    iText = "Private Sub CommandButton1_Click()"
    With ThisWorkbook.VBProject.VBComponents("Лист01").CodeModule
         For iCount = 1 To .CountOfLines
             If InStr(1, .Lines(iCount, 1), iText, vbTextCompare) Then
                .DeleteLines iCount, 4: Exit For
             End If
         Next
    End With
End Sub

Правда все вышеопубликованные варианты могут найти, например, 'Комментарий к PRIVATE Sub CommandButton1_Click() , что не шибко соответствует поставленной задаче, поэтому при построчном сравнении можно замутить что-то вроде этого :

Private Sub FindCodeInLine2()
    Dim iText$, iCount&
    
    iText = "Private Sub CommandButton1_Click()" & "*"
    With ThisWorkbook.VBProject.VBComponents("Лист01").CodeModule
         For iCount = 1 To .CountOfLines
             If Trim(.Lines(iCount, 1)) Like iText Then
                .DeleteLines iCount, 4: Exit For
             End If
         Next
    End With
End Sub

или

Private Sub FindCodeInLine2()
    Dim iText$, iCount&
    
    iText = "Private Sub CommandButton1_Click()"
    With ThisWorkbook.VBProject.VBComponents("Лист01").CodeModule
         For iCount = 1 To .CountOfLines
             If InStr(1, Trim(.Lines(iCount, 1)), iText, 1) = 1 Then
                .DeleteLines iCount, 4: Exit For
             End If
         Next
    End With
End Sub

[who]

Спасибо за подсказку. Очень может быть, что в ином случае найдётся и другое совпадение, но в моём случае код ищется для удаления строк созданных кодом и комментов там не будет, а если комменты и будут, сомневаюсь, что я буду описывать целиком имя процедуры (или как оно там правильно называется)

В моём проекте программно посредством VBA копируется при необходимости один из листов (в моём случае не первый и второй, но это отношения к делу не имеет) со всем содержимым, при этом на первом листе дублируется кнопка и на неё добавляется кусок кода (суть моего топика), тоже посредством VBA.
Также этот лист, при необходимости, программно удаляется и созданная при его создании кнопка с первого листа тоже удаляется (ну так надо мне!).
Так вот нужно удалить код подвешенный на скопированную кнопку листа1, что-бы в дальнейшем при копировании кнопки вновь не появлялось дубликатов кода и чтобы в конце-концов код не засорялся

Т.е. в моём случае вряд ли будет повтор искомого текста.
Как-то так...

[pashulka]

Не нравится такой комментарий, возьмите другой случай - когда комментируется и оставляется весь предыдущий вариант.

'Private Sub CommandButton1_Click()
'    CommandButton1.BackColor = vbRed
'    CommandButton1.ForeColor = vbWhite
'End Sub

Private Sub CommandButton1_Click()
    MsgBox "Такой вариант нам подходит"

End Sub

А вообще, основной смысл поста был в другом.