Автосумма

[andrew__86]

Приветствую всех. Нужно сделать в ворде автосумму. Чтобы посчитать например весь столбец можно с помощью Selection.InsertFormula Formula:="=SUM(ABOVE)", NumberFormat:="". Вопрос в том, как сделать чтобы считались только выделенные ячейки?

[Ципихович Эндрю]

В ворде таблица проходим по всем ячейкам, если выделено, значит она наша
считываем в память заносим число и двигаемся дальше

[andrew__86]

Тоесть нужен цикл?

[Ципихович Эндрю]

естественно

[viter.alex]

Если ячейки выделены не подряд, то не получится, т.к. макросом нельзя получить список этих ячеек или, перебирая, определить, что ячейка выбрана. А если ячейки выбраны подряд, тогда можно так:

Sub SelCellsSum()
  Dim Rng As Range
  Dim i As Long, j As Long, k As String
  i = Selection.Cells(1).RowIndex
  j = Selection.Cells(Selection.Cells.Count).RowIndex
  k = Chr(64 + Selection.Columns.Last.Index)
  Set Rng = Selection.Columns.Last.Cells(Selection.Columns.Last.Cells.Count).Range
  Rng.Delete
  Rng.Collapse wdCollapseStart
  ActiveDocument.Fields.Add Rng, wdFieldEmpty, "=SUM(" & k & i & ":" & k & j & ")"
End Sub

Формула будет вставлена в последнюю ячейку столбца, в котором находятся выбранные ячейки. Работать будет для таблиц с не более, чем с 26-ю столбцами.

[Ципихович Эндрю]

>Если ячейки выделены не подряд, то не получится
А что можете их выделить не подряд?

[viter.alex]

Конечно, могу. С зажатым Ctrl

[andrew__86]

i - первая ячейка j - последняя, а что делает код написанный дальше, как считается сумма, по идее должен быть цикл?
И ещё, что изменить в коде, чтобы считались ячейки в строке?

[viter.alex]

Никакого цикла. Сумма, как и раньше, считается формулой. Например, SUM(A1:A4) посчитает сумму первых четырёх ячеек первого столбца.
немного изменю. Теперь будет считать и по строкам и/или по столбцам, в зависимости от выбранных ячеек

Sub SelCellsSum()
  Dim Rng As Range
  Dim i As Long, j As Long, k As String, n As String
  i = Selection.Cells(1).RowIndex
  j = Selection.Cells(Selection.Cells.Count).RowIndex
  k = Chr(64 + Selection.Columns.First.Index)
  n = Chr(64 + Selection.Columns.Last.Index)
  'Ячейка для вывода результата.
  If Selection.Columns.Count = 1 Then
    'Если выбран один столбец, то в последнюю ячейку столбца
    Set Rng = Selection.Columns.Last.Cells(Selection.Columns.Last.Cells.Count).Range
  ElseIf Selection.Rows.Count = 1 Then
    'Если выбрана одна строка, то в последнюю ячейку строки
    Set Rng = Selection.Rows.Last.Cells(Selection.Rows.Last.Cells.Count).Range
  Else
    'Если выбрано несколько строк и столбцов, то в последнюю ячейку таблицы.
    Set Rng = Selection.Tables(1).Range.Cells(Selection.Tables(1).Range.Cells.Count).Range
  End If
  Rng.Delete
  Rng.Collapse wdCollapseStart
  'Формула для вычисления суммы диапазона
  ActiveDocument.Fields.Add Rng, wdFieldEmpty, "=SUM(" & k & i & ":" & n & j & ")"
End Sub

[Ципихович Эндрю]

было
4
46
53
23
Последнюю в столбце он стёр и написал сумму без последней = 103
Непорядок