обработка массива из несмежных диапазонов

[Bape}l{ka]

здравствуйте еще раз)))

помогите, плз, уже клинит о.О
есть прекрасная функция, честно взятая с отсюда
она отлично работает с выделенным смежным диапазоном, НО если диапазоны несмежные, то в массив попадают только значения из первого Area, а остальное не обрабатывается(??) я уж все передумала и перепробовала, но так и не поняла, как сделать, чтоб обрабатывало все выделенное помогите плз!!

Function UniqueValues(ByVal arr) As Collection
    ' функция получает в качестве параметра массив любой размерности
   ' возвращает коллекцию уникальных НЕПУСТЫХ значений
   Set UniqueValues = New Collection: On Error Resume Next
    For Each v In arr
        v = Trim(v): If Len(v) Then UniqueValues.Add CStr(v), CStr(v)
    Next v
End Function


Sub ПримерИспользования_UniqueValues()
    For Each v In UniqueValues(Selection.Value)
        MsgBox v
    Next
End Sub

[EducatedFool]

Добавил в ту статью новую функцию:

Function UniqueValuesFormRange(ByVal ra As Range) As Collection
    ' функция получает в качестве параметра диапазон ячеек
   ' возвращает коллекцию уникальных НЕПУСТЫХ значений
   Set UniqueValuesFormRange = New Collection: On Error Resume Next
    Dim ar As Range
    For Each ar In ra.Areas
        For Each v In ar.Value
            v = Trim(v): If Len(v) Then UniqueValuesFormRange.Add CStr(v), CStr(v)
        Next v
    Next ar
End Function

Пример её использования:

Sub ПримерИспользования_UniqueValuesFormRange()
    For Each v In UniqueValuesFormRange(Selection)
        Debug.Print v
    Next
End Sub

[Bape}l{ka]

спасибо, EducatedFool хD

я думала в том же направлении, недодумала.. с синтаксисом не разобралась =ь