Вывод физ. и stack'ого адреса переменной / 8086

[coNsept]

Всем привет! Ребят имею представление как получить стековый адрес и физ. адрес переменной, но не могу понять как можно вывести все это дело на экран.
То есть я как понимаю, я получу значение адреса, значение переводить в Hex, с Hex'а в строку и только потом вывод.
За ранее благодарен за любую подсказку.

[vadimych]

Скажем, адрес в ax.

lea bx,hextable
lea di,buf
mov cx,4
@@:
rol ax,4
push ax
and al,0fh
xlatb
stosb
pop ax
loop @b
..................
hextable db '0123456789ABCDEF'
buf db 4 dup (?),'$'

[coNsept]

Почему-то компилятор ругается на Rol Ax, 4 - то есть если явно указать 4.
А если так к примеру Mov Cl, 4; Rol Ax, Cl - так нормально.

[vadimych]

Надо указать в начале кода, что используются команды .186 процессора, тогда можно без cl обойтись.

[coNsept]

Не совсем твой вариант у меня работает, к сожалению.
Когда пытаюсь вывести buf у меня вообще программа висит.
Sorry, что такой тугой, я просто только не давно перебрался с Сях на Асмус

lea bx,hextable
lea di,buf
mov cx,4
@@:
rol ax,4
push ax
and al,0fh
xlatb
stosb
pop ax
loop @b

lea dx, [buf]
mov ah, 9H
int 21h

[vadimych]

Может быть, дело в квадратных скобках? Попробуй mov dx,offset buf.

[coNsept]

vadimych так тоже не работает, но все равно спасибо за помощь. Вообщем я разобрался с выводом адреса, может кому пригодиться.

.186

.Model Small

.Stack 100H

.DATA
 Buffer DW 0ABH, 0CDH, 0EFH
 
.CODE

InitSeg Proc
 Mov Ax, @DATA
 Mov Ds, Ax
 Ret
InitSeg Endp

PressKey Proc
 Mov Ax, 0C07H
 INT 21H
 Ret
PressKey Endp

Exit Proc
 Mov Ax, 4C00H
 INT 21H
 Ret
Exit Endp

GetSymbol Proc
 Push Bp
 Mov Bp, Sp
 Sub Sp, 4H
 Mov Dx, [Bp + 4H]
 Mov Ah, 02h 
 INT 21H
 Mov Sp, Bp
 Pop Bp
 Ret
GetSymbol Endp

EndLine Proc
 Mov Dx, 0AH 
 Mov Ah, 02H
 INT 21H
 Ret
EndLine Endp

OutputAddr Proc
 Push Bp
 Mov Bp, Sp
 Sub Sp, 4H
 Mov Ax, [Bp + 4H]
 Mov Cl, 16-4
 Xchg Dx, Ax
@Cicle:
 Mov Ax, Dx
 Shr Ax, Cl
 And Al, 0FH
 Add Al, '0'
 Cmp Al, '9'
 Jbe @NotHexDigit
 Add Al, 'A'-('9'+1)
@NotHexDigit:
 int 29H
 Sub Cl, 4
 Jnc @Cicle
 Mov Sp, Bp
 Pop Bp
 Ret
OutputAddr Endp

Begin:
 Call InitSeg
 Mov Dx, Buffer
 Push Dx
 Call OutputAddr 
 Mov Dx, ' '
 Push Dx
 Call GetSymbol
 Lea Dx, Buffer
 Push Dx
 Call OutputAddr
 Call EndLine 
 Call PressKey
 Call Exit
End Begin

[vadimych]

coNsept, не знаю, почему у тебя не пошёл мой вариант. Вот рабочий код. Сначала выводится адрес hextable, потом - стековый адрес возврата из программы.

.model tiny
.code
.186
org 100h
start:

lea ax,hextable
mov bx,ax
lea di,buf
call @f

inc di
mov bp,sp
mov ax,[bp+2]
call @f

exit:
lea dx,buf
mov ah, 9H
int 21h

xor ax,ax
int 16h
ret
@@:
mov cx,4
@@:
rol ax,4
push ax
and al,0fh
xlatb
stosb
pop ax
loop @b
ret

hextable db '0123456789ABCDEF'
buf db 4 dup (?),' ',4 dup (?),'$'
end start