условия сравнение

[Михаил2261]

Здравствуйте
Подскажите как правильно записать условия сравнения для строки
из 5 чисел
А В С D E
3 8 4 18 12
Если А < B , C < B, D > C, E < D удалить строку или отметить другим цветом
спасибо

[motorway]

if ( (Cells(1,1).Value<Cells(1,2).Value) And (...)) Then Rows("1:1").Delete

В ... пишете нужные условия аналогично первому, где Cells(i,j) - ячейка с i строкой и j столбцом

[IgorGO]

Sub PaintRows()
  Dim r As Long, rg
  For r = Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
    If (Cells(r, 1) < Cells(r, 2)) _
    And (Cells(r, 3) < Cells(r, 2)) _
    And (Cells(r, 4) > Cells(r, 3)) _
    And (Cells(r, 5) < Cells(r, 4)) Then
      If IsEmpty(rg) Then Set rg = Rows(r) Else Set rg = Application.Union(rg, Rows(r))
    End If
  Next
  If Not IsEmpty(rg) Then rg.Interior.Color = 55555
End Sub

[SAS888]

С позволения уважаемого IgorGO, хочу отметить, что при проверке нескольких (больше 2-х) условий лучше не использовать оператор And, т.к. в этом случае Excel проверяет все условия (присваивает True или False), независимо от того, совпали они или нет. Затем между ними выполняет And. Т.е. если 1-е условие не совпало, то нет смысла проверять остальные. Лучше воспользоваться вложенными If. Код чуть длиннее, но время выполнения процедуры будет меньше. Например, так:

Sub PaintRows()
    Dim r As Long, rg As Range: Application.ScreenUpdating = False
    For r = 1 To Cells(Rows.Count, 1).End(xlUp).Row
        If Cells(r, 1) < Cells(r, 2) Then
            If Cells(r, 3) < Cells(r, 2) Then
                If Cells(r, 4) > Cells(r, 3) Then
                    If Cells(r, 5) < Cells(r, 4) Then
                        If rg Is Nothing Then Set rg = Rows(r) Else Set rg = Union(rg, Rows(r))
    End If: End If: End If: End If: Next
    If Not rg Is Nothing Then rg.Interior.ColorIndex = 6
    'If Not rg Is Nothing Then rg.EntireRow.Delete
End Sub

Закомментированная строчка кода - это на случай, если нужно не выделять ячейки, а удалять строки.
Также, обратите внимание:
1. Возможно, что Вам понадобится проверка значений ячеек как на пустоту, так и на тип данных (числовое значение).
2. Предлагаемый макрос просматривает столбцы "A:E" с 1-й строки до последней заполненной в столбце "A". Достаточно ли Вам этого условия?

[Teslenko_EA]

Здравствуйте уважаемые господа.
по поводу "..лучше не использовать оператор And..", согласен и потому предлагаю использовать подобный варианты ветвления:

        If Cells(r, 1) > Cells(r, 2) Then
        ElseIf Cells(r, 3) > Cells(r, 2) Then
        ElseIf Cells(r, 4) < Cells(r, 3) Then
        ElseIf Cells(r, 5) > Cells(r, 4) Then
        ElseIf rg Is Nothing Then
            Set rg = Rows(r)
        Else
            Set rg = Union(rg, Rows(r))
        End If

но с утверждением "..проверяет все условия (присваивает True или False), независимо от того, совпали они или нет.." согласиться не могу, проблема только в осмыслении результатов выражения, а они никогда не противоречат логике.

Евгений.

[SAS888]

...но с утверждением ... согласиться не могу...

Почему? Оператор And осуществляет логическое перемножение значений. Для этого, по меньшей мере, эти значения должны быть в наличии. Т.е. Excel (в нашем случае) получает для каждого сравнения логический результат (True или False), затем выполняет саму операцию And (логическое перемножение всех Boolean значений).

[Михаил2261]

спасибо большое