CMD-файл

[Nonon]

Здравствуйте все.
Вот такой возник у меня вопрос.
Задание: написать CMD-файл, резервного копирования файлов из текущего каталога на носитель, задаваемый переменной окружения TMPDISK, в каталог, задаваемый переменной окружения TMPDIR, без перезаписи существующих там файлов. Шаблоны файлов передаются через список параметров.
Ок, напишем,вот что вышло:
REM носитель
set tmpdisk=f:\
REM Каталог приемник
SET tmpdir=33\
REM шаблон копируемых файлов например *.bat
set lis=*.*
copy %lis% %tmpdisk%%tmpdir%/v
Но препод ругается, что "надо копировать КАЖДЫЙ файл и анализировать код возврата с выводом сообщения на экран успешно или нет произошло копирование". Подскажите, будьте добры, как быть.

[Serge_Bliznykov]

лень сейчас писать готовый код, но, думаю,
что Ваш преподаватель добивается от Вас
использования оператора for ...
что-то типа такого:
for %%f in (*.*) do call s1.cmd %%f
Ну, разумеется, вместо вызова s1.cmd должно быть ваше копирование с проверкой...

[Nonon]

Да, спасибо, так я ему и писала:
REM носитель
set tmpdisk=f:\
REM Каталог приемник
SET tmpdir=33\
REM шаблон копируемых файлов например *.bat
set list=*.*
For %%f IN ("*.*") do copy %list% %tmpdisk%%tmpdir%/v%%f

Но ответ был, "команда
copy %list% %tmpdisk%%tmpdir%/v%%
может закончиться неуспешно, надо проверить ее код возврата командой IF".
Подскажите, пожалуйста, как это можно реализовать?

[Serge_Bliznykov]

1) справочник комадной строки доступен в Windows

XP Prof "hh ntcmds.chm"  
XP home "hh ntcmds.chm::/ntcmds.htm" 
w2k "hh windows.chm::/ntcmds.htm"

то, что в кавычках написано, написать и выполнить в командной строке.

2) думаю, что Вам поможет анализ возвращаемого ERRORLEVEL
if [not] errorlevel число команда

errorlevel число
Условие выполняется, если предыдущая команда, обработанная интерпретатором команд Cmd.exe, завершилась с кодом, равным или большим числа.

примерно так можно решить Вашу задачу:

@echo off

REM носитель
set tmpdisk=f:\
REM Каталог приемник
SET tmpdir=33\
REM шаблон копируемых файлов например *.bat
set list=*.pas


for %%c in (%list%) do (
    set "file=%%c"
    set "folder=%tmpdisk%%tmpdir%"
    call :MyCopy
)
goto :eof

:MyCopy
@echo off
if exist "%folder%%file%" (
      echo "File %folder%%file% already exist."
      goto :cont
      )
rem echo "coping file: %file% to %folder%%file%"
COPY "%file%" "%folder%%file%" > nul
IF ERRORLEVEL 1 echo "Error while copying file: %file%"
:cont
goto :eof

[Nonon]

Большое спасибо Вам за такой содержательный ответ.