Как узнать, есть ли в заданном диапазоне буквы...

[CyberMen]

Как узнать, есть ли в заданном диапазоне буквы.
Пример моего кода (привожу отрывок из кода):

Set myRange = ActiveDocument.Range(Start:=0, End:=0)
    For Each oCell In Selection.Tables(1).Range.Cells
            myRange.SetRange Start:=oCell.Range.Start, End:=(oCell.Range.End - 1)
            If IsNumeric(myRange) = True Then

Как узнать, есть ли в диапазоне myRange буквы.
Вообще, смысл кода в чём? В том, чтобы просмотреть ячейки всех таблиц в документе (я как всегда косячу - в данном случае приведён пример для одной таблицы), и если там есть только цифры, то сделать определённое действие. На др. форумах я нашёл решение этой проблемы, но вчера столкнулся с цифрами, разделёнными точками и запятыми, и эти цифры уже не считаются за цифры.

[viter.alex]

Нужно действовать поиском с помощью подстановочных знаков.

[CyberMen]

viter.alex
а типа функции instr - нет ничего поменьше, да по-проще?
Это получается ты предлагаешь:

with myRange.Find
и поехало

?
А вот как-то ещё функции можно делать (есть процедуры, а есть функции) - в них не будет быстрее? Т.е. я в функцию помещаю myRange. Функция определяет, есть ли там буквы, и возвращает (раздражает это слово) True или False.
Я просто функции ещё ни разу не делал.

[viter.alex]

Нет, я предлагаю искать сразу по всей таблице.

Sub test()
  Dim oRng As Range
  With Selection.Tables(1).Range.Find
    .Text = "<[0-9]@[.,][0-9]@>"
    .MatchWildcards = True
    .Replacement.Font.Color = wdColorRed
    .Execute Replace:=wdReplaceAll
  End With
End Sub

Найдёт в таблице все числа, разделённые точкой или запятой, занимающие всю ячейку, и окрасит их в красный цвет
Хотя можно и перебором, только лучше использовать Do…Loop, а не For Each, для увеличения быстродействия

Sub test2()
  Dim oCell As Cell
  Dim sCellText As String
  Set oCell = Selection.Tables(1).Range.Cells(1)
  Do Until oCell Is Nothing
    sCellText = Left(oCell.Range.Text, Len(oCell.Range.Text) - 2)
    'Проверяем является ли числом текст в ячейке сам по себе _
    или если в нём точку заменить на запятую
    If IsNumeric(sCellText) Or IsNumeric(Replace(sCellText, ".", ",")) Then
    
    End If
    'Переход в следующую ячейку
    Set oCell = oCell.Next
  Loop
End Sub

[CyberMen]

Вот такое решение нашёл благодаря Replace. Сам бы наверное если и догадался об этом, то очень ‎не скоро:‎

If IsNumeric(myRange) = True Or IsNumeric(Replace(myRange, ",", "")) = True Or ‎IsNumeric(Replace(myRange, ".", "")) = True Then

В документе 192 таблицы – проверка была проведена за 2 минуты. Хорошая работа.‎

viter.alex
Не понятно только, зачем точку менять на запятую.‎

[viter.alex]

Сообщение от CyberMen

…viter.alex
Не понятно только, зачем точку менять на запятую.‎

Затем, что работа функции IsNumeric зависит от принятого в системе десятичного разделителя (задаётся в панели управления). По умолчанию, в русской операционной системе используется запятая, поэтому число вида "25.3" не будет признано числом.

[CyberMen]

viter.alex
да, я уже в курсе, мне на др. форуме объяснили. Просто в моём случае встречались 2 и 3 точки (запятые) в одном числе и это уже не воспринималось, как число.
Вот сейчас думаю, а если по ошибке в цифре будут и точки и запятые, что тогда делать?