Как с помощью FileSystemObject

[Rossoman]

Как с помощью FileSystemObject сделать следующее:
1) как найти все файлы по маске x??x.txt например

2) как считать в переменные 2 и 4 строку файла dd.txt например

неужели с помощью вба так не сделать?

[viter.alex]

Можно это сделать только с помощью VBA
Найти все файлы по маске:

Sub FindFiles()
  'Имя файла
  Dim sFileName As String
  'Путь к папке с файлами
  Dim sPath As String: sPath = "d:\Мои документы\Программы\test\"
  'Маска для файлов
  Dim sMask As String: sMask = "x??x.txt"
  'Сообщение
  Dim sMsg As String
  
  sFileName = Dir(sPath & sMask)
  Do While Len(sFileName) > 0
    sMsg = sMsg & sFileName & vbCrLf
    sFileName = Dir
  Loop
  MsgBox "В папке """ & sPath & """ найдены следующие файлы, соответствующие маске """ & _
          sMask & """:" & vbCrLf & sMsg, vbInformation + vbOKOnly, "Поиск файлов по маске"
End Sub

Чтение из файла нужных строк

Sub ReadString()
  'Переменные, в которые читать строки. Объявлены как Variant, _
  но если известен тип данных, которые нужно получить из файла, _
  то можно указать этот тип при объявлении
  Dim a, b
  'Содержимое строки
  Dim sLine As String
  'Счетчик строк
  Dim nLineCntr As Long: nLineCntr = 1
  'Идентификатор для файла
  Dim FileNum As Byte
  
  FileNum = FreeFile 'Получаем свободный идентификатор для файла
  'Открываем файл для чтения
  Open "d:\Мои документы\Программы\test\dd.txt" For Input As FileNum
  Do While Not EOF(FileNum)
    Line Input #1, sLine 'Читаем построчно
    Select Case nLineCntr
      Case 2
        a = sLine
      Case 4
        b = sLine
    End Select
    nLineCntr = nLineCntr + 1
  Loop
  Close FileNum
  Debug.Print "a:=" & CStr(a) & " b=" & CStr(b)
End Sub

[Rossoman]

спасибо тебе огромное ) еще бы было круто, если бы мне кто-нибудь показал поиск файла по маске, но с поиском по вложенным папкам тоже.
filsesearch не предлагать)

[viter.alex]

Делал я такую штуку, вот мой код, а ты можешь разобраться и подогнать под свои потребности

Dim scolFilePaths As New Collection 'пути ко всем файлам, которые должна обрабатывать программа
'Перечисление для определения диапазона поиска файлов.
'Можно обойтись и без него, но зачем?
Enum WhichFilesProceed
  wfpOnlyInRootFolder = 0
  wfpInRootAndSubFolders = 1
  wfpOnlyInSubFolders = 2
End Enum
'Получение списка файлов
Sub GetFilePaths(sRootFolderPath As String, sMask As String, WhichFiles As WhichFilesProceed)
  Dim FSO As Object
  Dim oFldr As Object
  Dim oSubFldr As Object
  Dim sFileName As String
  
  Set FSO = CreateObject("Scripting.FileSystemObject")
  
  If Right(sRootFolderPath, 1) <> "\" Then sRootFolderPath = sRootFolderPath & "\"
  
  'Получаем имена файлов из корневого каталога
  If WhichFiles = wfpOnlyInRootFolder Or WhichFiles = wfpInRootAndSubFolders Then
    sFileName = Dir(sRootFolderPath & sMask)
    While Len(sFileName) > 0
      scolFilePaths.Add sRootFolderPath & sFileName
      sFileName = Dir
    Wend
  End If
  
  'Получаем имена файлов из всех подкаталогов
  If WhichFiles = wfpOnlyInSubFolders Or WhichFiles = wfpInRootAndSubFolders Then
    Set oFldr = FSO.GetFolder(Left(sRootFolderPath, Len(sRootFolderPath) - 1))
    For Each oSubFldr In oFldr.SubFolders
      sFileName = Dir(oSubFldr.Path & "\" & sMask)
      While Len(sFileName) > 0
        scolFilePaths.Add oSubFldr.Path & "\" & sFileName
        sFileName = Dir
      Wend
    Next
  End If
  Set FSO = Nothing: Set oFldr = Nothing: Set oSubFldr = Nothing
End Sub

[Teslenko_EA]

Здравствуйте Rossoman.
образцы не решают Вашу задачу, но дают представление о "многих вещах" в том числе о том, что не "только с помощью VBA"....
Евгений.

[Rossoman]

Сообщение от viter.alex

Найти все файлы по маске:

Sub FindFiles()
  'Имя файла
  Dim sFileName As String
  'Путь к папке с файлами
  Dim sPath As String: sPath = "d:\Мои документы\Программы\test\"
  'Маска для файлов
  Dim sMask As String: sMask = "x??x.txt"
  'Сообщение
  Dim sMsg As String
  
  sFileName = Dir(sPath & sMask)
  Do While Len(sFileName) > 0
    sMsg = sMsg & sFileName & vbCrLf
    sFileName = Dir
  Loop
  MsgBox "В папке """ & sPath & """ найдены следующие файлы, соответствующие маске """ & _
          sMask & """:" & vbCrLf & sMsg, vbInformation + vbOKOnly, "Поиск файлов по маске"
End Sub

Уважаемый, помогите пожалуйста, изменить данный код, чтоб искал с учетом по дате? т.е. сначала например самый поздний файл, который был создан...просто мне именно в таком порядке конечно было бы лучше проводить с ними операции..
Нужно в данном случае использовать массив?

P.S. С вашей помощью я почти переписал свой скрипт)) еще раз спасибо.

[viter.alex]

Ну, если в лоб, тогда так. Записываем пути к файлам в массив, потом массив сортируем:

Sub FindFiles()
  'Имя файла
  Dim sFileName As String
  'Путь к папке с файлами
  Dim sPath As String: sPath = "d:\Мои документы\Программы\test\"
  'Маска для файлов
  Dim sMask As String: sMask = "x??x.txt"
  'Сообщение
  Dim sMsg As String
  Dim ar() As String
  ReDim ar(0)
  
  sFileName = Dir(sPath & sMask)
  Do While Len(sFileName) > 0
    ar(UBound(ar)) = sFileName
    sMsg = sMsg & sFileName & vbCrLf
    sFileName = Dir
    If Len(sFileName) <> 0 Then ReDim Preserve ar(UBound(ar) + 1)
  Loop
  'Сортировка методом пузырька
  Dim i As Integer, j As Integer, sTmp As String
  For i = 0 To UBound(ar)
    For j = 0 To UBound(ar) - 1 - i
      If FileDateTime(sPath & ar(j)) < FileDateTime(sPath & ar(j + 1)) Then
        sTmp = ar(j)
        ar(j) = ar(j + 1)
        ar(j + 1) = sTmp
      End If
    Next j
  Next i
  sMsg = Join(ar, vbCrLf)
  MsgBox "В папке """ & sPath & """ найдены следующие файлы, соответствующие маске """ & _
          sMask & """ (самый поздний файл первый):" & vbCrLf & sMsg, vbInformation + vbOKOnly, "Поиск файлов по маске"
End Sub

[SAS888]

как считать в переменные 2 и 4 строку файла dd.txt например

С применением объекта FileSystemObject это действительно проще. Например, так:

Sub ReadStrings()
    Dim a As String, b As String, t As String: On Error Resume Next
    t = CreateObject("Scripting.FileSystemObject").OpenTextFile("D:\Мои документы\Программы\test\dd.txt", 1).ReadAll
    a = Application.Clean(Split(t, Chr(10))(1)): b = Application.Clean(Split(t, Chr(10))(3)): ts.Close
    MsgBox a & " : " & b
End Sub

поиск файла по маске, но с поиском по вложенным папкам тоже

Для получения всех подпапок используйте свойство SubFolders метода GetFolder объекта FileSystemObject, и в каждой подпапке для поиска требуемых файлов организуйте цикл Do...Loop, который позволяет использовать маску.