Как сохранить файл в текущей папке?

[sid99999]

Пытаюсь сохранить лист в отдельном файле, но он сохраняется в МоиДокументы. Помогите сохранить его в текущей папке. Вот код:

Sub Создание_отчета ()
'
' Создание_отчета Макрос
' Макрос записан 22.05.2009 (RostikS)
'

'
Sheets("месяц").Select
Sheets("месяц ").Copy
Cells.Select
Selection.Copy
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Range("A1").Select
Application.CutCopyMode = False
ActiveWorkbook.SaveAs Filename:= _
"Отчет.xls", FileFormat:= _
xlNormal, Password:="", WriteResPassword:="", ReadOnlyRecommended:=False _
, CreateBackup:=False
ActiveSheet.Shapes("Button 3").Select
Selection.Cut
End Sub

[EducatedFool]

Чтобы файл сохранялся в нужной папке, надо указывать полный путь к файлу:
(хотя можно и установить рабочим каталогом Excel папку с текущим документом)

Sub Создание_отчета()
    НовоеИмяФайла = "Новый файл"
    НовыйПуть = Replace(ThisWorkbook.FullName, ThisWorkbook.Name, НовоеИмяФайла)
    
    Sheets("месяц").Copy ' на основе этого листа создаётся новая книга
    ActiveWorkbook.SaveAs НовыйПуть ' сохраняем эту новую книгу с одним листом
    ActiveWorkbook.Close False ' закрываем книгу без сохранения
End Sub

Только учтите, что лист с именем месяц должен присутствовать в файле. (иначе макрос выдаст ошибку)

[sid99999]

Спасибо! Все работает.