Дубль строки таблицы

[Rita2018]

Добрый день!
Помогите пожалуйста с таблицей, мне необходимо(как в примере) в таблицу I1:K9 чтоб попадали данные из заполненной таблицы A1:D5 - при этом чтоб ячейки из столбца A,B дублировались, а данные из столбцов C, D были по строчкам соответственно
Заранее спасибо!!!

[Elixi]

Rita2018, для вашего файла

Sub Rita2018_Test()
    Dim Rw&, RwF&, RwL&, i&
    
    RwF = 2
    RwL = Cells(Rows.Count, 1).End(xlUp).Row
    ReDim M((RwL - 1) * 2, 2)

    M(0, 0) = Cells(1, 1)
    M(0, 1) = Cells(1, 2)
    M(0, 2) = Mid(Cells(1, 3), 1, Len(Cells(1, 3)) - 1)
        
    For Rw = RwF To RwL
        i = i + 1
        M(i, 0) = Cells(Rw, 1)
        M(i, 1) = Cells(Rw, 2)
        M(i, 2) = Cells(Rw, 3)
        i = i + 1
        M(i, 0) = M(i - 1, 0)
        M(i, 1) = M(i - 1, 1)
        M(i, 2) = Cells(Rw, 4)
    Next

    Cells(12, 9).Resize(UBound(M, 1) - LBound(M, 1) + 1, _
                        UBound(M, 2) - LBound(M, 2) + 1) = M
End Sub

[Rita2018]

Elixi, спасибо большое!!!
А ещё подскажите, а если мне нужна таблица(результат) на новом листе с ячейки A1?
Set ShP=Sheets(2)
......

ShP.Cells(12, 9).Resize(UBound(M, 1) - LBound(M, 1) + 1, _
UBound(M, 2) - LBound(M, 2) + 1) = M

[Elixi]

да, Rita2018, если лист существует, можно и так
а если листа нет или, может быть, на втором листе важные данные

    ' ... можно лист добавить
    Sheets.Add after:=Sheets(ActiveSheet.Index)
    ' ... наименовать, например так
    ActiveSheet.Name = "MySheet" _
                        & "_" & Format(Date, "yyyy-mm-dd") _
                        & "_" & Format(Time, "hh-mm-ss")
    Cells(1, 1).Resize(UBound(M, 1) - LBound(M, 1) + 1, _
                        UBound(M, 2) - LBound(M, 2) + 1) = M
    ' ... и после записи данных поправить ширину столбцов
    Columns.AutoFit