макрос пакетной конвертации docx в doc

[caute]

чё-то не идет, вечером поковыряюсь часок, спасибо

[caute]

Последний совет с ходу сработал. Вышло так:

Sub SaveAllFormData()
    Dim doc As Document
    Dim fileName As String
Dim path As String:  path = "c:\abc\" ' путь к папке с файлами
    fileName = Dir(path & "*.docx")

     ' Loop through all .docx files in that path
    Do While fileName <> ""
        Set doc = Application.Documents.Open(path & fileName)

' Save form data
    ActiveDocument.SaveAs fileName:=doc.FullName & ".doc", FileFormat:= _
        wdFormatDocument, LockComments:=False, Password:="", AddToRecentFiles:= _
        True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:= _
        False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False

        doc.Close wdDoNotSaveChanges
        fileName = Dir
    Loop
End Sub

Спасибо, добрые люди!

[caute]

а чтобы и вложенные папки макрос обрабатывал в указанной папке, что надо добавить в код?

[Serge_Bliznykov]

Сообщение от caute

а чтобы и вложенные папки макрос обрабатывал в указанной папке, что надо добавить в код?

код для рекурсивного поиска файлов в поддиректориях можно взять отсюда - http://www.ammara.com/access_image_f...er_search.html

[caute]

спасибо, а как этот код вставить в имеющийся код?

[Serge_Bliznykov]

Сообщение от caute

спасибо, а как этот код вставить в имеющийся код?

ну, типа так:

Sub SaveAllFormData()
    Dim path As String:  path = "c:\abc\" ' путь к папке с файлами    
    Call RecursiveDir(path, "*.docx", True)
End Sub


Public Function RecursiveDir(strFolder As String, _
                             strFileSpec As String, _
                             bIncludeSubfolders As Boolean)

    Dim strTemp As String
    Dim colFolders As New Collection
    Dim vFolderName As Variant

    Dim doc As Document

    'Add files in strFolder matching strFileSpec to colFiles
    strFolder = TrailingSlash(strFolder)
    strTemp = Dir(strFolder & strFileSpec)
    Do While strTemp <> vbNullString

        ' конвертация тут
        Set doc = Application.Documents.Open(strFolder & strTemp)

        ' Save form data
        ActiveDocument.SaveAs fileName:=doc.FullName & ".doc", FileFormat:= _
        wdFormatDocument, LockComments:=False, Password:="", AddToRecentFiles:= _
        True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:= _
        False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False

        doc.Close wdDoNotSaveChanges


        strTemp = Dir
    Loop

    If bIncludeSubfolders Then
        'Fill colFolders with list of subdirectories of strFolder
        strTemp = Dir(strFolder, vbDirectory)
        Do While strTemp <> vbNullString
            If (strTemp <> ".") And (strTemp <> "..") Then
                If (GetAttr(strFolder & strTemp) And vbDirectory) <> 0 Then
                    colFolders.Add strTemp
                End If
            End If
            strTemp = Dir
        Loop

        'Call RecursiveDir for each subfolder in colFolders
        For Each vFolderName In colFolders
            Call RecursiveDir(strFolder & vFolderName, strFileSpec, True)
        Next vFolderName
    End If

End Function


Public Function TrailingSlash(strFolder As String) As String
    If Len(strFolder) > 0 Then
        If Right(strFolder, 1) = "\" Then
            TrailingSlash = strFolder
        Else
            TrailingSlash = strFolder & "\"
        End If
    End If
End Function

не проверял.

[caute]

как часы! благодарствую

[Serge_Bliznykov]

Всегда пожалуйста!

[сфинкс]

свыше 10 лет существует бесплатная программа
переводящая именно из docx в doc

и тоже то же для других офисных

проводник - курсор на файл docx - сохранить как
и сохраняет там же в doc за секунды

и тоже то же для других офисных