Заменить часть текста на формулу Word VBA

[bdfy]

Предположим нужно мне вставить в ворд текст
"где К_р – повышающий коэффициент, зависящий от присвоенного рабочему разряда;"
Я использую для вставки текста вот такой код

Public Function insert_textN(ByVal text As String, ByVal oRng As Object, _
Optional ByVal newparagraph As Boolean = True, Optional ByVal HEADER As Integer = 0)


  
  With oRng
    .Collapse wdCollapseEnd
    If newparagraph Then .InsertParagraphbefore
    
    If InStr(text, "_") > 0 And False Then
       Dim RegExp, myMatches, myMatch
      Set RegExp = CreateObject("VBScript.RegExp")
      RegExp.Global = True
      RegExp.Pattern = "[ ]+"
      Set myMatches = RegExp.Execute(text)
      Dim SplitArray()
      ReDim SplitArray(myMatches.Count)
      p = 0
      i = 0
      For Each myMatch In myMatches
          SplitArray(i) = Mid(text, p + 1, myMatch.FirstIndex - p)
          p = myMatch.FirstIndex + myMatch.Length
          i = i + 1
      Next
      SplitArray(i) = Mid(text, p + 1)
      Set oDoc = oRng.document

      
      For Each x In SplitArray
          Debug.Print x & " " & InStr(x, "_")
          If InStr(x, "_") > 0 Then
              Call eq_text_addN(" " & x, oDoc.Paragraphs(oDoc.Paragraphs.Count).Range, False, False)
          Else
              Call insert_textN(" " & x, oDoc.Paragraphs(oDoc.Paragraphs.Count).Range, False, False)
          End If
          
          'oDoc.Paragraphs(oDoc.Paragraphs.Count).Range
      Next
      
      Exit Function
    End If
    
        
    .InsertAfter text
    
  End With
  oRng.Collapse wdCollapseEnd
  oRng.Select
  If HEADER <> 0 Then
  oRng.Paragraphs.Style = oRng.document.Styles("Заголовок " & HEADER)
  End If
  
  
  
End Function

Но вот как корректно оформить переменные (они с нижними индексами) ? загонять текст в нижний индекс я пробовал - работает посредственно, форматирование рано или поздно может сбиваться при оформлении документа. В идеале вместо К_р нужно вставлять формулу.
Как это сделать ? Вставлять можно формулы нового редактора формул (2007 и выше) он понимает подчеркивание в принципе

[Казанский]

Сообщение от bdfy

If InStr(text, "_") > 0 And False Then

Лихо отключили всю эту сложную обработку

Сообщение от bdfy

загонять текст в нижний индекс я пробовал - работает посредственно, форматирование рано или поздно может сбиваться при оформлении документа.

Ни разу не встречал такого, чтобы нижний индекс слетал (в отличие от формул). Это очень простое форматирование.
Можно включить нижний индекс для текста после _ и до следующего пробела при помощи поиска-замены Ворда:

Public Function insert_textN(ByVal text As String, ByVal oRng As Object, _
Optional ByVal newparagraph As Boolean = True, Optional ByVal HEADER As Integer = 0)

  With oRng
    .Collapse wdCollapseEnd
    If newparagraph Then .InsertParagraphBefore
    
    .InsertAfter text
    With .Find
      .ClearFormatting
      .Replacement.ClearFormatting
      With .Replacement.Font
        .Superscript = False
        .Subscript = True
      End With
      .text = "(_)([! ]@ )"
      .Replacement.text = "\2"
      .Forward = True
      .Wrap = wdFindStop
      .Format = True
      .MatchCase = False
      .MatchWholeWord = False
      .MatchAllWordForms = False
      .MatchSoundsLike = False
      .MatchWildcards = True
      .Execute Replace:=wdReplaceAll
    End With
  End With
  oRng.Collapse wdCollapseEnd
  oRng.Select
  If HEADER <> 0 Then
  oRng.Paragraphs.Style = oRng.Document.Styles("Заголовок " & HEADER)
  End If
  
End Function

Sub test()
'вставить фразу с несколькими нижними индексами после второго слова в документе
  insert_textN "где К_р – повышающий коэффициент, зависящий от присвоенного рабочему Р_аб разряда;", _
    ActiveDocument.Words(2)
End Sub

[bdfy]

А я вот видел как форматирование сбивается
+дело в том что переменная то может быть и несколько сложнее чем К_1
Например может быть нижний и верхний индекс, например К_а^1 в редакторе формул это корректно проходит, а индексами не сделать...
Как этот код заставить работать если Word документ заполняется из VBA Excel ?
.Execute Replace:=2
как будто не проходит команда

[Казанский]

Сообщение от bdfy

Как этот код заставить работать если Word документ заполняется из VBA Excel ?
.Execute Replace:=2

Там в коде и другие вордовские константы есть.
Option Explicit в начале модуля помогает выявить неопределенные идентификаторы.
Можете в VBA Excel подключить библиотеку Ворда: Tools - References - Microsoft Word... , тогда константы будут определены.

[bdfy]

нашел я ошибку текст вставлялся после поиска - а значит искать было не в чем) константы и т.п. тут не при чем.