Замена данных при совпадении

[franchesko_totti]

Добрый день!
Появилась еще одна задача, помогите пожалуйста.
Необходимо чтобы соответственно фамилиям в листе Railway заполнялись еще и соседние столбцы "Кредиторы" и "МВЗ". Все данные соответственно в листе "Кредиторы".

[Hugo121]

Ну так это всё так же чревато ошибками - недостаточно Фамилия И., даже Фамилия И.О. маловато - уже в этом куцем примере в случае с Кузнецов успех мог бы быть только 50%.
Нужно ID.

[franchesko_totti]

Так может после использования формулы по изменению фамилий использовать просто ВПР?

[Hugo121]

Если Вы фамилии/ID получите в таком виде, что можно использовать ВПР() (или индекс-поискпоз) - то можете использовать.
Но если данных десятки тысяч - я бы использовал тоже макрос, если это не разовая задача (алгоритм тот же, только в словарь помещаем не фамилию, а номер строки, и извлекаем не фамилию, а по номеру строки данные из массива).

[franchesko_totti]

А если не трудно можете написать кодировку правильную, я сам ошибок наделаю наверняка). В этом деле мало что понимаю).

[Hugo121]

Скорректировал:

Option Explicit

Sub tt()
    Dim a(), b(), i&, t$, tarr

    With Sheets("Кредиторы")
        a = Range(.[C2], .Range("A" & Rows.Count).End(xlUp)).Value
    End With

    With CreateObject("scripting.dictionary")
        For i = 2 To UBound(a)
            tarr = Split(a(i, 2))
            t = tarr(0) & "|" & Left(tarr(1), 1)
            .Item(UCase(t)) = i
        Next

        With Sheets("Railway")
            b = Range(.[G5], .Range("E" & Rows.Count).End(xlUp)).Value
        End With

        For i = 1 To UBound(b)
            b(i, 1) = Replace(b(i, 1), ".", " ")
            b(i, 1) = Replace(b(i, 1), "=", " ")
            tarr = Split(b(i, 1))
            t = tarr(0) & "|" & Left(tarr(1), 1)
            If .exists(t) Then
                b(i, 1) = a(.Item(t), 2)
                b(i, 2) = a(.Item(t), 1)
                b(i, 3) = a(.Item(t), 3)
            End If
        Next
    End With

    With Sheets("Railway")
        Range(.[G5], .Range("E" & Rows.Count).End(xlUp)).Value = b
    End With

End Sub

Привязка всё так же к Фамилия И - что ненадёжно и косячит, не применять в работе!

[franchesko_totti]

Спасибо!!!