Работа со строкой в VBA

[Knyazev_I]

Доброго времени суток, уважаемы!
Есть столбец в Excel, строки которого содержат информацию следующего формата 16/20+12/18+12/18RCP. Т.е. 16/20 - наименование, "+" - разделительный символ.
В соседнем столбце строки содержат информация тип 75/53/22, т.е. количество для каждого наименования.
Каким образом разделить информацию в ячейках и в итоге получить отчет вида:
16/20 = сумма 150
12/18 = сумма 106
12/18RCP = сумма 44

[Hugo121]

Split значений в массивы, соспоставление элементов массивов. Вот таким образом

[Knyazev_I]

Не поможете с кодом? Можно за $. Если да, то стоимость.
Забыл уточнить что строки (16/20+12/18+12/18RCP и 75/53/22) могут иметь более чем 3 типа.

[SAS888]

Например, так:

Sub qq()
    Dim i As Long, j As Integer, a(), b(), ai, bi
    a = Range("A1:B" & Cells(Rows.Count, 1).End(xlUp).Row).Value
    ReDim b(1 To UBound(a, 1), 1 To 1)
    For i = 1 To UBound(a, 1)
        ai = Split(a(i, 1), "+"): bi = Split(a(i, 2), "/")
        If UBound(ai) = UBound(bi) Then
            For j = LBound(ai) To UBound(ai)
                b(i, 1) = b(i, 1) & ai(j) & " = сумма " & bi(j) & ", "
            Next
            b(i, 1) = Left$(b(i, 1), Len(b(i, 1)) - 2)
        End If
    Next
    [C1].Resize(UBound(b, 1), 1).Value = b
End Sub

Пример во вложении. Откройте файл и запустите макрос "qq".
Для более конкретного ответа прикрепите файл с данными.

[Knyazev_I]

SAS888, спасибо.
Подскажите как получить отчет вида
16/20 = сумма 150
12/18 = сумма 106
12/18RCP = сумма 44
Т.е. сумма всех значений по каждому обнаруженному наименованию.

[SAS888]

Прикрепите файл с исходными данными...

[Hugo121]

И с результатом!
И это нужно было сделать сразу, с вопросом.

[Knyazev_I]

Можно отчет в функции MessageBox?

[Hugo121]

В msgbox?
Пожалуйста
Добавил пару строк в код уважаемого SAS888 (а лишнее закомментировал):

Option Explicit

Sub qq()
    Dim i As Long, j As Integer, a(), ai, bi, k 'b()
    a = Range("N2:O" & Cells(Rows.Count, 15).End(xlUp).Row).Value
    'ReDim b(1 To UBound(a, 1), 1 To 1)
    With CreateObject("Scripting.Dictionary"): .comparemode = 1

        For i = 1 To UBound(a, 1)
            If Len(a(i, 1)) Then
                ai = Split(a(i, 2), "+"): bi = Split(a(i, 1), "/")
                If UBound(ai) = UBound(bi) Then
                    For j = LBound(ai) To UBound(ai)
                        .Item(ai(j)) = .Item(ai(j)) + --bi(j)
                        'b(i, 1) = b(i, 1) & ai(j) & " = сумма " & bi(j) & ", "
                    Next
                    'b(i, 1) = Left$(b(i, 1), Len(b(i, 1)) - 2)
                End If
            End If
        Next

        For Each k In .keys
            MsgBox k & " = сумма " & .Item(k)
        Next

    End With

End Sub

[Казанский]

1. Можно! А что Вы потом с ним делать будете - PrintScreen?
2. Свернутые строки включать в отчет или нет?