Копирование кнопки макросом и присвоение новой кнопке своего имени

[who]

У меня есть лист1, на котором есть некоторое количество кнопок.
Среди них есть CommandButton2
как, находясь на листе2, макросом скопировать эту кнопку в конкретное место на листе1, например спозиционировать новую кнопку по ячейке С24 и задать новое имя кнопке (.Name, а не .Caption), чтобы я знал это имя и использовал в дальнейшем в работе.

[Aleksandr H.]

Form Control

To copy a button from one sheet to another preventing the automatic name change use the below code. Excel by default gives a new name to a copied button (even on a different sheet) so you have to rename it to match the name of the button youre copying.

Use CopyButton() sub to achieve it. There are 4 required parameters

from - sheet name to copy the button from
btnName - the name of the control you want to copy
toWorksheet - target worksheet
rng - target range to associate with the button

Sub CopyPasteButton()
    CopyButton "SRC", "Button 1", "TRGT", "B10"
End Sub

Private Sub CopyButton(from As String, btnName As String, toWorksheet As String, rng As String)
    Application.ScreenUpdating = False
    Sheets(from).Shapes(btnName).Copy
    Sheets(toWorksheet).Activate
    Sheets(toWorksheet).range(rng).Select
    Sheets(toWorksheet).Paste
    Selection.ShapeRange.Name = btnName
    Application.ScreenUpdating = True
End Sub

[who]

Спасибо, принцип понял!

[pashulka]

Альтернативный вариант :

Private Sub Test()
    With Лист1.CommandButton2.Duplicate 'Лист1.OLEObjects("CommandButton2").Duplicate
         .Top = Лист1.[C24].Top
         .Left = Лист1.[C24].Left
         .Name = "CommandButton3" 
    End With
End Sub

[who]

тоже сапасибо!
а как записать на эту новую кнопку тем же макросом макрос? это конечно другая тема, но не нашёл похожего

[Aleksandr H.]

Попробуй
http://www.mrexcel.com/forum/excel-q...ml#post3681329

[pashulka]

Один из возможных вариантов
(необходимо доверить доступ к Visual Basic Project)

With ThisWorkbook.VBProject.VBComponents("Лист1").CodeModule
     .InsertLines 1, "Private Sub CommandButton3_Click()"
     .InsertLines 2, "    MsgBox ""Hello, Word"""
     .InsertLines 3, "End Sub"
End With

P.S.

ThisWorkbook.VBProject.VBComponents("Лист1").CodeModule.InsertLines 1, _
"Private Sub CommandButton3_Click()" & vbCrLf & _
"   MsgBox ""Hello, Word""" & vbCrLf & _
"End Sub"

ThisWorkbook.VBProject.VBComponents("Лист1").CodeModule.AddFromString _
"Private Sub CommandButton3_Click()" & vbCrLf & _
"   MsgBox ""Hello, Word""" & vbCrLf & _
"End Sub"

[who]

Спасибо будем пробовать...

[who]

может тыкните носом в какой-нибудь мануальчик с перечнем и описанием команд VBA для работы с проектом VBA (я что-то не нашёл)? в частности меня интересует поиск номера строки с заданным текстом, и удаление этой строки.

[Aleksandr H.]

Частностный вариант поиска, сравнения и удаления.
http://programmersforum.ru/showpost....8&postcount=17

и еще
http://lmgtfy.com/?q=vba+excel%2C+%D...BE%D0%BA%D0%B8