Открыть word из excel

[Вадим12091965]

Здравствуйте. Excel и word находятся в одной папке. На листе Excel находится кнопка "Справка" для вызова word "Справка". Как будет выглядеть код? Спасибо.

[VictorM]

Открыть word из excel

ну это уже перебор.
Да таких тем на форуме (и не только нашем) несколько десятков, а может и сотен.
Неужели сложно воспользоваться поиском?

[VictorM]

Excel и word находятся в одной папке

А это что?
Документы или сами программы?
Да и что за справка?
Справка по Word?

[Скрипт]

Вариант 1. Удобен для написания макроса, т.к. когда будем ставить точку, будет появляться список с членами.
Для работы кода нужно в VBA сделать: Tools - References... - Microsoft Word версия Object Library.

Sub Procedure_1()
    
    'Tools - References... - Microsoft Word версия Object Library.
    'Создание переменной "myWord".
    'Эта переменная будет именем программы "Word".
    'Через эту переменную можно работать с программой "Word"
        'как будто мы находимся в программе "Word".
    Dim myWord As Word.Application
    
    'Запуск программы "Word".
    'Назначение программе "Word" имени "myWord" .
    Set myWord = CreateObject(Class:="Word.Application")
    
    'Отображение программы "Word" на мониторе,
        'чтобы если произойдёт какая-нибудь ошибка, мы
        'могли закрыть программу "Word" крестиком в правом верхнем углу.
    myWord.Visible = True
    
    'Открытие Word-файла.
    myWord.Documents.Open Filename:=ActiveWorkbook.Path & "\" & "Doc1.docx"
    
End Sub

Вариант 2. Нужно использовать тогда, когда макрос будет протестирован с помощью Варианта 1. Этот Вариант позволяет использовать макрос на разных компьютерах без настройки каждого компьютера.

Sub Procedure_2()
    
    Dim myWord As Object
    
    
    Set myWord = CreateObject(Class:="Word.Application")
    myWord.Visible = True
    myWord.Documents.Open Filename:=ActiveWorkbook.Path & "\" & "Doc1.docx"
    
End Sub

[Вадим12091965]

Скрипт. Спасибо. 2 вариант работает отлично.
VictorM. На форумах я искал, и на нашем форуме нашел вариант

Private Sub CommandButton1_Click()

    Dim WordApp As Object
    Dim wrdDoc As Object
    Dim tmpDoc As Object
    Dim WDoc As String
'   Dim myDoc As String
'    myDoc = "onoie?eainou-aaoi"
    WDoc = ThisWorkbook.Path & "\" & Справка & ".doc"
'    Debug.Print WDoc
    Err.Number = 0
    On Error Resume Next

    Set WordApp = GetObject(, "Word.Application")
 
'   Debug.Print "WordApp " & WordApp
   
    'If WordApp Is Nothing Then
    If Err.Number <> 0 Then
         ' no current word application
        Set WordApp = CreateObject("Word.application")
        Set wrdDoc = WordApp.Documents.Open(WDoc)
   ' WordApp.Visible = True
    Else
         ' word app running
        For Each tmpDoc In WordApp.Documents
            If StrComp(tmpDoc.FullName, WDoc, vbTextCompare) = 0 Then
                 ' this is your doc
                Set wrdDoc = tmpDoc
                Exit For
            End If
        Next
        If wrdDoc Is Nothing Then
             ' not open
            Set wrdDoc = WordApp.Documents.Open(WDoc)
        End If
    End If
    WordApp.Visible = True
WordApp.DisplayAlerts = False
WordApp.ActiveWindow.Selection.WholeStory
'open_word = WordApp

End Sub

, но он открывал не конкретный документ, а оболочку Word. Я не знал что добавить в код, чтобы открыть конкретный документ. "Справка" - это название документа.