Не хочет переименовывать папку.

[Rin]

Приветствую вас, гринго. Есть один маленький вопрос по коду, который(вопрос в смысле) описан выше в названии темы:

 Str_Move_Enter db 'Vvedite katalog$',0
 Str_Move_New db 'Vvedite novyj katalog$',0
 Str_Move_Error db 'Oshibka$',0
 buf2 db 254,0,254 dup ('?')
 buf3 db 254,0,254 dup ('?')
...................

;----------------------------Процедура вывода сообщения
OutMsg proc
   mov ah,9
   int 21h 
   ret
OutMsg endp

;----------------------------Ожидание ввода
Vvod proc
   mov ah,0Ah
   int 21h
   ret
Vvod endp

;----------------------------Процедура перехода на новую строку
NextStr proc
   push dx
   mov dx,offset str_ent
   call OutMsg
   pop dx
   ret
NextStr endp

;----------------------------Процедура переименования
P_Move proc

mov dx, offset Str_Move_Enter
call outmsg
call nextstr
   mov dl,24h
   mov ah,2
   int 21h
mov dx, offset buf2
call Vvod

call nextstr
mov dx, offset Str_Move_New
call outmsg
call nextstr
   mov dl,24h
   mov ah,2
   int 21h
mov dx, offset buf3
call Vvod
call nextstr
lea bx, buf2
movzx   si, byte ptr [bx+1] 
mov     byte ptr [bx+si+1], 0 

lea bx, buf3
movzx   si, byte ptr [bx+1] 
mov     byte ptr [bx+si+1], 0 
lea dx, buf2+2
lea di, buf3+2

mov ah,56h
int 21h
jnc move_ok

mov dx, offset Str_Move_Error
call outmsg
call nextstr

move_ok:
   ret
P_Move endp

[Serge_Bliznykov]

ого. редко так бывает.
два разных человека задают вопрос с одной и той же проблемой!
(это я про тему Ассемблер(TASM) переименовать файл )

принципиальных ошибок я не вижу,
только, на вашем месте, я бы убедился, что
1) перед вызовом 56H функции, у Вас регистр ES показывает именно на область, где расположена buf3 (ES:DI должно показывать на buf3, где должно находится корректное ASCIIZ имя.

2) я бы проверил, что там в buf2 и buf3 перед вызовом функции..
Один малюсейникй пробельчик в имени или перед ним, или перед обязательным заверщающим нулём и всё. баста. Функция не отработает!

3) Вы не забываете, что функция 56H (как и все функции MS DOS) работают исключительно с КОРОТКИМИ именами файлов/папок?!

[Rin]

На счёт коротких имён в DOS не забываю=). Спасибо за подсказку проверки
содержимого buf`ов, сам что-то тупанул . На место последнего символа записывался нуль.
вместо:

lea bx, buf2
movzx   si, byte ptr [bx+1] 
mov     byte ptr [bx+si+1], 0 

lea bx, buf3
movzx   si, byte ptr [bx+1] 
mov     byte ptr [bx+si+1], 0

надо это:

lea bx, buf2
movzx   si, byte ptr [bx+1] 
mov     byte ptr [bx+si+2], 0

lea bx, buf3
movzx   si, byte ptr [bx+1] 
mov     byte ptr [bx+si+2], 0