Перевод из строки в число и обратно

[AsmBeginer]

Здравствуйте. Приведите, пожалуйста, пример исходника на асме, как строчное (символьное) представление числа перевести в действительное число, чтоб можно было совершать над ним действия, а потом опять перевести в строчное. Если можно, асм под ДОС.

[rpy3uH]

посмотри вот это

[AsmBeginer]

я извиняюсь, я имел ввиду по ДОС.
или подскажите, вот чтобы перевести строчное в численное, нужно от строчного отнять 48? А наоборот, чтоб получить из численного строчное, нужно прибавить 48?

[Stilet]

Если ты кодиш на MASM то можеш вызывать dwtoa. Она как раз это и делает.

[AsmBeginer]

Stilet, посмотрел. Понял как сделать. Действительно, нужно отнимать и прибавлять 48, или символ '0', который кадируется как 048 или 30h. Это я посмотрел в реализации dwtoa. Правда, сам алгоритм пока не понял, уж больно он "накручен" и по моему, в нем есть лишние строки )

[Stilet]

Хм. Вот у меня завалялась старая лаба, перевода чисел до 100 на асме в строку.

         mov esi, offset Caption
	 mov eax, 82 ; Это число которое нужно перевести
	 mov ecx, 10
	 div cl
	 add ax,'00'
	 mov [esi],ax

Я не претендую (ессно) на аплодисменты, но может как идея прокатит.

Пардон, я тут точнее вспомнил и слегка поменял код )

[Rikki-Tikki]

Сообщение от AsmBeginer

я извиняюсь, я имел ввиду по ДОС.
или подскажите, вот чтобы перевести строчное в численное, нужно от строчного отнять 48? А наоборот, чтоб получить из численного строчное, нужно прибавить 48?

а если я работаю на ТАСМе.
если отнять 30h, мы получаем численное значение - в какой системе счисления?

[Mikl___]

Rikki-Tikki
ASCII кодировка цифр '0' = 30h, '1' = 31h, '2'= 32h, ..., '9'=39h отнимаешь от символа 30h и получаешь его числовое значение;
в двоичной системе счисления есть только символы '0' и '1', а '3', '4', ..., '9' нет;
в восмеричной есть символы от '0' до '7', а '8' и '9' нет;
в шестнадцатеричной к символам от '0' до '9' добавляются символы 'A'=41h, 'B'=42h, 'C'=43h, 'D'=44h, 'E'=45h, 'F'=46h от этих символов нужно отнимать уже 37h или 57h если они будут записаны маленькими буквами 'a'=61h, ..., 'f'=66h

[alexcoder]

;преобразование числа из ах в десятичную строку по адресу es:di
;ax - число
;es:di - адрес буфера приемника
printdec proc

	push cx	;сохраняем регистры
	push dx
	push bx
	mov bx,10	;основание системы
	XOR CX,CX	;в сх будет количество цифр в десятичном числе
@@m1:	XOR dx,dx       ;обнудяем dx
	DIV bx		;делим число на степени 10
	PUSH DX		;и сохраняем остаток от деления(коэффициенты при степенях) в стек
	INC CX		;увеличиваем количество символов в числе
	TEST AX,AX	;преобразовали все число?
	JNZ @@m1	;если нет, то продолжить
@@m2:	POP AX		;восстанавливаем остаток от деления
	ADD AL,'0'	;преобразовываем число в ASCII символ
	STOSb		;сохраняем в буфер
	LOOP @@m2		;все цифры
	pop bx		;восстанавливаем регистры
	POP dx
	POP cx
	RET
printdec endp

;-----------------------------------------------------------------------
;Преобразование строки в число
;на входе ds:si ссылается на ASCIIZ строку, которую нужно преобразовать
; на выходе в ax - число.
;-----------------------------------------------------------------------
str2dw:
	xor dx,dx	;сумма
@lp1:	xor ax,ax
	lodsb		;берем cимвол
	test al,al	;если это нулев байт, то заканчиваем
	jz @ex
	cmp al,'9'	;Если это не цифра, то пропускаем
	jnbe @lp1
	cmp al,'0'      ;Если это не цифра, то пропускаем
	jb @lp1
	sub ax,'0'	;получаем цифровое значение
	shl dx,1	;умножаем сумму на 10
	add ax, dx
	shl dx, 2
	add dx, ax	;прибавляем текущее значение
	jmp @lp1
@ex:	mov ax,dx
	ret

[Mikl___]

alexcoder
Вот это перл!

shl dx,1	;умножаем сумму на 10
	add ax, dx
	shl dx, 2
	add dx, ax	;прибавляем текущее значение

Где вы такое откопали, признавайтесь! не понятно как, но работает!, молодца!
ax:= dx*2 + ax; dx:=dx*8; dx:=dx*8+dx*2+ax Какой у Вас право изощренный ум! Я в шоке!
эквивалентно: lea eax=[eax+edx*2] lea edx=[eax+edx*8]
"Классический" вариант

	xor dx,dx	;сумма
	mov ah,0
@lp1:	lodsb		;берем cимвол
	test al,al	;если это нулев байт, то заканчиваем
	jz @ex
	sub al,'0'	;получаем цифровое значение
	cmp al,9
	ja @lp1
	imul dx,10	;умножаем сумму на 10
	add dx, ax	;прибавляем текущее значение
	jmp @lp1