Задача: Замена слов местами в Microsoft Office Word

[andresss]

Привет друзья!

прошу вашей помощи в решении следующей задачи:

дано

BREINER, Laurence A. bla bla bla bla bla bla bla bla
BREIVIK, Patricia Senn. bla bla bla bla bla bla bla bla
BRENNER, Joël Glenn. bla bla bla bla bla bla bla bla

нужно

Laurence A BREINER. bla bla bla bla bla bla bla bla
Patricia Senn BREIVIK. bla bla bla bla bla bla bla bla
Joël Glenn BRENNER. bla bla bla bla bla bla bla bla

- что то вроде фамилию и имя правильно проставить
- в исходном файле всё одинаково, после первого слова идёт запятая, в конце точка



за ранее благодарю

[garik64]

Искать
(<*>)(,)(^32)(*)(.)
с подстановочными знаками, полужирное

Менять на
\4 \1

[andresss]

чет не получается, а если без жирного, просто замена, то как?

[garik64]

Что значит "не получается"? Всё получается. Либо Вы искали без подстановочных знаков, либо пример не отражает реального текста.

Но вот мне что пришло в голову: если фамилия будет двойная, типа "Иванов-Скворцов", тогда не сработает. Значит, делаем чуть по-другому (опять с подстановочными знаками):

Искать:

(^13)([A-Za-zА-Яа-я^32\-]@)(,)(^32)(*)(.)

Если вместо нормальных абзацев стоят мягкие – вместо (^13) писать (^l)

Менять на:

\1\5 \2

В любом случае - пример реального документа в студию!

Смысла нет помогать человеку, не зная точно, чего ему надо.

[andresss]

вот пример, это пдф файл изначально



там попадаются фамилии не только тройные, из четырех частей тоже

(там где скобки попадаются я их поудаляю)

спасибо за помощь

[garik64]

Да картинка-то зачем? И пдф не нужен. Вы ведь этот файл распознаёте и перегоняете в Ворд, верно? Вот и приложите кусок такого вордовского документа - просто вложением, не надо на стороннем хостинге. Это нужно затем, чтобы понять, где в нём знаки абзаца, где мягкие переносы и т.п.

Например, если каждая строка будет заканчиваться концом абзаца, тогда, конечно, получится фигня. Потребуется ещё одна предварительная операция.

там попадаются фамилии не только тройные, из четырех частей тоже

На всех должно сработать одинаково. Пока я не вижу, почему не срабатывает. Вероятно, Вы не ставите птичку "использовать подстановочные знаки".

[andresss]

еще раз спасибо за помощь

срабатывает как то через один, вот пример:

[viter.alex]

Простым перебором абзацев:

Sub SwapWords()
  Dim oRng As Range, oRngTemp As Range
  Dim oDoc As Document
  Dim sFirtsWord As String
  Dim oPar As Paragraph
  
  
  Set oDoc = ActiveDocument
  Set oPar = oDoc.Paragraphs.First
  
  Do Until oPar Is Nothing
    With oPar
      'Если абзац не пустой
      If Asc(.Range.Characters.First.Text) <> 13 Then
        'Запоминаем первое слово и удаляем его
        sFirtsWord = .Range.Words.First
        .Range.Words.First.Select 'Это для того, чтобы был виден процесс обработки
        .Range.Words.First.Delete
        'Теперь работаем с началом абзаца, чтобы удалить запятую и пробел
        Set oRngTemp = oDoc.Range(.Range.Start, .Range.Start)
        With oRngTemp
          .SetRange .Start, .End + .MoveEndUntil(" ")
          .Delete
        End With
        'Ищем, где оканчивается имя автора (первая точка с начала абзаца _
        и вставляем перед точкой запомненную фамилию с пробелом
        Set oRngTemp = oDoc.Range(.Range.Start, .Range.Start)
        With oRngTemp
          .SetRange .Start, .End + .MoveEndUntil(".") - 1
          .InsertAfter " " & sFirtsWord
        End With
      End If
      'Переход к следующему абзацу
      Set oPar = .Next
      DoEvents
    End With
  Loop
End Sub

Или с помощью поиска и замены с подстановочными знаками:

Sub SwapWords2()
  With ActiveDocument.Range.Find
    .Text = "(<[A-Z^0032]@>)(, )([A-z^0032\(\)]@)(\.)"
    .Font.Bold = True
    .Replacement.Text = "\3 \1\4"
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
End Sub

[andresss]

viter.alex первый макрос отлично справился!

большое всем спасибо :-)

p.s. a можно ли для каждого абзаца сделать следующее:
взять первое предложение до точки, запомнить его и вставить над самим абзацем.
example:

Edward Marriott
Edward Marriott. British, b. 1966. Genres: Travel/Exploration. Career: Author, journalist, and broadcaster. Works at Evening Standard. Publications: The Lost Tribe: A Harrowing Passage into New Guinea’s Heart of Darkness, 1997; Savage Shore: Life and Death with Nicaragua’s Last Shark Hunters, 2000. Address: c/o Evening Standard, Northcliffe House, 2 Derry St., London W8 5TT, England.

[viter.alex]

Сообщение от andresss

viter.alex первый макрос отлично справился!…

А второй не справился?

Ответ на вопрос: можно!