Формат числа

[mchip]

В документе есть числа типа:
0,0000106722000000000 .
Возможно ли автоматически отформатировать такие числа в формат:
1,067*10-5(десять в минус пятой)

[viter.alex]

Макросом. Искать такие числа, функцией FormatNumber преобразовывать в экспоненциальную форму, а затем поиском и заменой заменять на показатели степени.

[mchip]

А если через поля?

[viter.alex]

Через поля ты получишь число вида 1,067Е-5. А потом опять поиск и замена

[mchip]

А как в таком виде сделать?

[viter.alex]

Нет, с полями очень муторно получается. Мне казалось, что есть ключ поля, чтобы форматировать число в экспоненциальную форму, но я ошибался. Придётся всё делать макросом:

Sub FormatToExponential()
  Dim oDoc As Document: Set oDoc = ActiveDocument
  Dim bFound As Boolean
  Dim iEnd As Long
  'Заменяем число на экспоненциальную форму
  Do
    With oDoc.Range(iEnd, oDoc.Range.End).Find
      .Text = "[0-9][.,][0-9]@>" 'Ищем числа, разделенные точкой или запятой
      .MatchWildcards = True
      While .Execute
        bFound = .Found
        'Если в числе десятичный разделитель запятая, то заменяем её на точку
        .Parent.Text = Format(Val(Replace(.Parent.Text, ",", ".")), "0.000E+")
        iEnd = .Parent.End
      Wend
      bFound = Not bFound
    End With
  Loop Until bFound
  
  'Теперь ищем эти числа и готовим их для замены на показатель степени
  With oDoc.Range.Find
    .Text = "([0-9][.,][0-9]{3})(E)(*[0-9]@>)"
    .Replacement.Text = "\1·10#####\3"
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
  'Заменяем кодовую последовательность на показатель степени.
  With oDoc.Range.Find
    .Text = "#####(*[0-9]@>)"
    .Replacement.Text = "\1"
    .Replacement.Font.Superscript = True
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
End Sub

[mchip]

Спасибо! Но к сожалению макрос не хотелось бы применять.

[viter.alex]

К сожалению, полями не получится. Почему макрос не устраивает?

Есть одно хитрое поле, которое можно подрихтовать под твои потребности, но очень это запутано будет.
Вот код этого поля:

{QUOTE{ASK z "What +ve number do you in scientific notation form?"}{SET a{=abs(z)}}{SET b{=9-(a<10^9)-(a<10^8)-(a<10^7)-(a<10^6)-(a<10^5)-(a<10^4)-(a<10^3)-(a<10^2)-(a<10^1)-(a<10^0)-(a<10^-1)-(a<10^-2)-(a<10^-3)-(a<10^-4)-(a<10^-5)-(a<10^-6)-(a<10^-7)-(a<10^-8)}}{SET c{=int(a/10^b)+mod(a;10^b)/10^b}}"{a} in scientific notation form is {c \# 0,000}E{b \# +#;-#}."}

Работает это поле довольно просто.

1. Запрашивается число, которое нужно показать в экспоненциальной форме и записывается в закладку z. {ASK z "What +ve number do you in scientific notation form?"};
2. В закладку a записывается модуль введенного числа. {SET a{=abs(z)}}
3. Считается показатель степени и записывается в закладку b. {SET b{=9-(a<10^9)-(a<10^8)-(a<10^7)-(a<10^6)-(a<10^5)-(a<10^4)-(a<10^3)-(a<10^2)-(a<10^1)-(a<10^0)-(a<10^-1)-(a<10^-2)-(a<10^-3)-(a<10^-4)-(a<10^-5)-(a<10^-6)-(a<10^-7)-(a<10^-8)}}
4. Определяется основание введённого числа. Для этого складывается целая часть от деления этого числа на 10^b и дробная часть от деления этого числа на 10^b. Основание записывается в закладку с. {SET c{=int(a/10^b)+mod(a;10^b)/10^b}}
5. После чего всё это дело выводится в виде текста. "{a} in scientific notation form is {c \# 0,000}E{b \# +#;-#}."

Пример использования в приложении. Желаю успехов

[mchip]

Да и подгонять не надо только Е заменить на *10 и все!
Спасибо!

[viter.alex]

Можно еще выражение {b \# +#;-#} отформатировать как верхний индекс, и получится совсем красиво.

Осталось заметить, что это поле будет работать для чисел от 10^-18 до 10^9