Проход по всем словам, находящимся в переменной

[Ципихович Эндрю]

Здравствуйте, в переменную s текст попадает по коду:

Dim s As String
    'обрабатываемый текст в переменную
    s = Selection.Text

обрабатываю слова, находящиеся в переменной так:

 Dim Обрабатываемый_текст As Range
    'создать объект согласно обрабатываемому тексту в документе
    Set Обрабатываемый_текст = ActiveDocument.Range(Start:=Начало_обрабатываемого_текста_в_документе, End:=Конец_обрабатываемого_текста_в_документе)
 
    Dim Количество_обрабатываемых_слов_в_документе As Long
    Количество_обрабатываемых_слов_в_документе = Обрабатываемый_текст.Words.Count
  For u = 1 To Количество_обрабатываемых_слов_в_документе
......

Знаю, что

'последовательный проход по коллекции итератором быстрее, чем обращение к произвольному элементу по индексу
'For x In — переменная x называется итератором, объектом, в котором содержится ссылка на очередной элемент коллекции/массива
'For x = — переменная x называется индексом, порядковым номером произволного элемента коллекции/массива
1. Это так?
2. Как пройтись в данном случае по словам переменной? через For Each u In каков код?
Спасибо

[Скрипт]

Ципихович Эндрю, с помощью команды "Find" по идее быстро должно быть и в самом Word-документе, без помещения данных в переменную.
Сделать условие: "<*>" - поиск слова и поставить флажок "Подстановочные знаки".

[Ципихович Эндрю]

идёт обработка слов по порядку, какие они неизвестно, то есть строго цикл

[Скрипт]

Ципихович Эндрю, ну вот циклом и вести поиск.

Поиск быстрее работает, чем просмотр каждого Word-слова. Я предполагаю, что Word-документ состоит из двух частей: одной части, которая видима пользователю, вторая часть - это просто сплошной текст - что-то вроде HTML-кода. Вот команда "Find", мне так кажется, и ищет в этом HTML-тексте.

Можно попробовать использовать библиотеку "Microsoft VBScript Regular Expressions" для поиска в переменной. Может в этой библиотеке есть выражение для поиска слов и не надо ничего выдумывать, а воспользоваться уже готовым.

[Ципихович Эндрю]

может быть... такого не встречал, но пока хоть заменить
For u = 1 To Количество_обрабатываемых_слов_в_до кументе
на
For x In хх
как? что вместо х и хх?

[Скрипт]

Представленный код не считает частью слова знак подчёркивания "_", дефис (может ещё чего не считает). Поэтому нужно корректировать код.

Sub Procedure_1()

    Dim myRange As Word.Range
    Dim myFind As Word.Find
    
    '1. Можно попробовать ускорить работу кода:
        '1) перейтие в режим "Черновик";
        '2) отключить проверку правописания.
    
    '2. Создаём виртуальную закладку (аналогична обычной Word-закладке,
        'только виртуальная закладка существует только во время работы кода).
    'С помощью этой закладки будем передвигаться
        'в документе для поиска искомого.
    'С помощью виртуальной закладки удобно вести поиск, если
        'виртуальная закладка представлена точкой вставки, а не фрагментом
        'документа. Точка вставки - это аналогично мигающему курсору на мониторе.
    Set myRange = ActiveDocument.Range(Start:=0, End:=0)
    
    '3. Создаём объект, который будет искать.
    'Привязываем этот объект поиска к нашей виртуальной закладке.
    Set myFind = myRange.Find
    
    '4. Настраиваем объект поиска.
    '4.1. Выражение "<*>" означает: найти любое слово.
    'Кавычки, скобки, пробелы, знаки препинания игнорируются.
    myFind.Text = "<*>"
    
    '4.2. Включаем флажок "Подстановочные знаки".
    myFind.MatchWildcards = True
    
    '5. Делаем команды, пока есть результат поиска.
    Do While myFind.Execute = True
    
        '6. Если есть результат поиска, то виртуальная закладка "myRange"
            'окружит найденный текст.
        'Можно доступ так получить к найденному слову.
        'Вывод результата в View - Immediate Window.
        Debug.Print myRange.Text
        
        '7. Превращаем виртуальную закладку снова в точку вставки.
            'А именно: перемещаем виртуальную закладку в конец
            'найденного фрагмента и поиск продолжится оттуда.
        myRange.Collapse Direction:=wdCollapseEnd
    
    Loop
    
    '8. Сообщение, что работа кода завершена.
    MsgBox "Работа кода завершена.", vbInformation

End Sub

[Ципихович Эндрю]

замурно, надо с этим переспать...