проблема с Do While

[dsadik91]

Здравствуйте!
Помогите, пожалуйста, исправить код.
ТЗ: ексель книга, в ней 2 листа, на первом идет просчет, на втором таблица-прайс, нужно с помощью макроса копировать ячейку из листа с прайсом, вставлять в ячейку листа с расчетом, копировать из нее результат и вставлять в новую ячейку на лист с прайсом.
Макрос написан работает но только для 1 ячейки, а нужно чтобы он по листу с прайсом вниз шел до момента пока строчки не кончатся.
Сейчас код такой:

Sub Макрос1()
'
' Макрос1 Макрос
'

 Do While Cells(n, 1).Value <> ""
'
    Range("A2").Select
    Selection.Copy
    Sheets("Лист1").Select
    Range("J7").Select
    ActiveSheet.Paste
    Range("E42").Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("для прайса").Select
    Range("K2").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
Loop

End Sub

[Казанский]

попробуйте

Sub Макрос1()
Dim n&

For n = 2 To Cells(Rows.Count, 1).End(xlUp).Row
    Sheets("Лист1").Range("J7") = Cells(n, "A")
    Cells(n, "K") = Sheets("Лист1").Range("E42")
Next

End Sub

[dsadik91]

спасибо огромное!!!! все получается)))