Создание закладки

[sunnyws]

Пишем макрос по созданию закладки.

Private Sub CommandButton1_Click()
Dim Bm As String

Bm = ActiveDocument.Bookmarks.Add
Bm = Replace(Selection.Text, " ", "_")
Selection.Range
'Set MyBook = Selection.Range(Start:=1, End:=10)
'If Selection.Range > 10 Then

If Selection.Range < 10 Then
 TextBox1 = MsgBox("Ошибка", vbOKOnly + vbCritical, "Ошибка")
End If
End Sub

Не получается создать закладку, в которой пробелы и запятые будут заменяться на подчеркивание, а именем закладки будут первые 10 символов. Закладка должна автоматически создаваться если выделить текст в документе и нажать кнопку формы.
Подскажите пожалуйста, что не так в коде? Заранее спасибо

[Казанский]

Может, так? На подчеркивание заменяются точки, запятые, пробелы.

Private Sub CommandButton1_Click()
If Selection.Characters.Count < 10 Then
    MsgBox "Текст слишком короткий!", vbCritical, "Ошибка"
Else
    ActiveDocument.Bookmarks.Add Replace$(Replace$(Replace$(Left$(Selection, 10), ".", "_"), " ", "_"), ",", "_"), Selection.Range
End If
End Sub

[sunnyws]

Спасибо.
А вот еще по этому макросу вопрос, не могу разобраться с проверкой:
Если выделено больше 10 символов, то в идентификатор закладки записываются только первые 10 выделенных символов, и если выделенный текст начинается с цифры, то в начало идентификатора приписывается буква "а".
Там в коде выше было, поняли только, что надо использовать что-то вроде

Set MyBook = Selection.Range(Start:=1, End:=10)
If Selection.Range > 10 Then

читаем мсдн, но там пока ничего в тему найти не смогли =(

[Казанский]

Сорри, упустил про первые 10. Так:

Private Sub CommandButton1_Click()
Dim s$
If Selection.Characters.Count < 10 Then
    MsgBox "Текст слишком короткий!", vbCritical, "Ошибка"
Else
    s = Replace$(Replace$(Replace$(Left$(Selection, 10), ".", "_"), " ", "_"), ",", "_")
    If IsNumeric(Left$(s, 1)) Then s = "a" & s
    ActiveDocument.Bookmarks.Add s, Selection.Range
End If
End Sub

[Ципихович Эндрю]

точка, пробел, запятая
не всё - что нельзя применять в имени закладки!!

[Казанский]

Согласен, добавил:

Option Compare Text

Private Sub CommandButton1_Click()
Dim s$, i&

If Selection.Characters.Count < 10 Then
    MsgBox "Текст слишком короткий!", vbCritical, "Ошибка"
Else
    s = Left(Selection, 10)
    For i = 1 To 10
        If Mid$(s, i, 1) Like "[!0-9A-ZА-ЯЁ]" Then Mid(s, i, 1) = "_"
    Next
    If Left$(s, 1) Like "[0-9_]" Then s = "a" & s
    ActiveDocument.Bookmarks.Add s, Selection.Range
End If
End Sub

[Ципихович Эндрю]

 If Mid$(s, i, 1) Like "[!0-9A-ZА-ЯЁ]" Then Mid(s, i, 1) = "_"

вроде Ucase не хватает

[Ципихович Эндрю]

ой не заметил
Option Compare Text
извините