Преобразование беспорядочного набора записей в наглядную форму

[Belfire]

День добрый,
Сам все не могу разобраться как из выгрузки "листа1" вывести необходимые значения в наглядную форму "листа2".
Должно выводится "id техники", "оператор ее использующий" и "признак смены" с последующей соответствующей этим значениям "количество замеров". Причем один и тот же оператор должен выводится единоразово если у него не было иного "признака смены" и "количество замеров" в этой записи по оператору суммируется.
на картинке возможно разъяснил что должно получиться в итоге более понятнее. Буду благодарен помощи)
Пока не выходит найти подходящий код для доработки под свой цикл по отбору всех записей одного "id" с выводом относящихся к нему данных + еще мне не совсем понятно как осуществить суммирование ячеек "количества замеров"

Sub Test()
'Объявление переменных
    Dim lastRow As Long
'Определение заполненной крайней строки
    lastRow = Worksheets(1).Cells(Rows.Count, 2).End(xlUp).Row
    lastRow = CInt(lastRow)

на картинке постарался разъяснить что в итоге должно получиться. Буду благодарен помощи)

[Aleksandr H.]

Сводная чем не выход?
att.jpg

и как вариант - код

Sub DoWork()
    Dim wks1 As Worksheet
    Dim wks2 As Worksheet
    Dim lastRow As Integer
    Dim sJoinedString As String
    Dim dict As Scripting.Dictionary
    Dim value_ As Integer
    Dim ar() As String
    Dim i As Integer
    Set wks1 = Sheets("Лист1")
    Set wks2 = Sheets("Лист2")
    Set dict = CreateObject("Scripting.Dictionary")
    With wks1
        lastRow = .Cells(.Rows.Count, "B").End(xlUp).Row
        For i = 2 To lastRow
            sJoinedString = .Cells(i, "A").Value2 & "@" & .Cells(i, "C").Value2 & "@" & .Cells(i, "E").Value2
            
            value_ = CInt(.Cells(i, "D").Value2)
            
            If Not dict.Exists(sJoinedString) Then
                dict.Add sJoinedString, value_
            Else
                dict(sJoinedString) = dict(sJoinedString) + value_
            End If
        Next i
    End With
    For i = 0 To dict.Count - 1
        ar = Split(dict.Keys(i), "@")
        wks2.Cells(i + 3, "A") = ar(0)
        wks2.Cells(i + 3, "B") = ar(1)
        wks2.Cells(i + 3, "C") = ar(2)
        wks2.Cells(i + 3, "D") = dict.Items(i)
    Next i
End Sub