Форматирование таблиц в документе

[IrinaNN]

Добрый день.

В процессе работы есть необходимость форматировать в единый стиль много документов, которые содержать таблицы и текст. (подготовка для HTML)

В макросах не сильна, только начинаю разбираться и читать. Помогите с написанием макроса.

В итоге документы должны иметь такой вид:
Шрифт Verdana 8
Удалить все колонтитулы
Таблицы по середине, по ширине страницы, границы определенные (файл прикрепляю).

Желательно, чтобы внутри таблиц первый столбец по левому краю выравнивание, Шапка - по центру, остальные ячейки по нижнему правому краю.

И совсем из нереального для понимания моего мозга: если есть пустые ячейки с таблице (без каких-либо символов), то вставить туда пробел.

Сама бы я разделила эту задачу на два макроса - один редактирует текст, второй - таблицы.

Буду рада любой помощи.

[shanemac51]

а у единицы измерения --какое выравнивание(табл 2, лево, центр)

---
и как вы планируете создавать НТМ(вордом очень много мусора)

[IrinaNN]

У единицы измерения центр. (но этот столбец не всегда есть в таблицах)

В HTML через сохранить как - веб-страница с фильтром....

[Step_UA]

С Word'ом не особо дружу, тестировал в 2007 ...

Sub Макрос()
    Application.ScreenUpdating = False
    With ActiveDocument.Range.Font ' установка шрифта
        .Name = "Verdana"
        .Size = 8
    End With
    
  Dim S As Section, Header As HeaderFooter
    ' удаляем колонтитулы
    For Each S In ActiveDocument.Sections
        For Each Header In S.Headers
            Header.Range.Delete
        Next
        For Each Header In S.Footers
            Header.Range.Delete
        Next
    Next

  Dim colCount&, rowCount&, Center&, i&, j&, y&
  Dim Col As Range, Table As Table, EmptyCell$
  
    EmptyCell = Chr(13) & Chr(7)
    On Error Resume Next
    For Each Table In ActiveDocument.Tables ' для всех таблиц
        With Table
            ' установка рамки
            .Borders(wdBorderHorizontal).LineStyle = wdLineStyleOutset
            .Borders(wdBorderVertical).LineStyle = wdLineStyleOutset
            .Borders.OutsideLineStyle = wdLineStyleOutset
                
            colCount = .Columns.Count   ' количество колонок
            rowCount = .Rows.Count      ' количество строк
            
            ' поиск строки после заголока
            For i = 2 To rowCount
                Err.Clear
                For j = 1 To colCount
                    y = .Cell(i, j).Range.Bold
                    If Err.Number Then Exit For
                Next
                If j > colCount Then Exit For
            Next
            
            ' установка выравнивания для заголовка
            For Center = 1 To i - 1
                For j = 1 To colCount
                    With .Cell(Center, j)
                        .Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
                        .VerticalAlignment = wdCellAlignVerticalCenter
                        If .Range.Text = EmptyCell Then .Range.Text = " "
                    End With
            Next j, Center
            
            ' поиск номера столбца "Единицы измерения"
            Set Col = .Range
            If Col.Find.Execute(FindText:="Единицы измерения", MatchWholeWord:=True) Then
                Center = Col.Cells(1).ColumnIndex
            Else
                Center = 0
            End If
            Err.Clear
            
            ' обход строк таблицы после заголовка
            For i = i To rowCount
                y = .Cell(i, 2).Range.Bold
                If Err.Number = 0 Then
                    With .Cell(i, 1)
                        .Range.ParagraphFormat.Alignment = wdAlignParagraphLeft
                        .VerticalAlignment = wdCellAlignVerticalCenter
                        If .Range.Text = EmptyCell Then .Range.Text = " "
                    End With
                    ' для всех ячеек строки i
                    For j = 2 To colCount
                        With .Cell(i, j)
                            If j = Center Then
                                .Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
                                .VerticalAlignment = wdCellAlignVerticalBottom
                            Else
                                .Range.ParagraphFormat.Alignment = wdAlignParagraphRight
                                .VerticalAlignment = wdCellAlignVerticalBottom
                            End If
                            If .Range.Text = EmptyCell Then .Range.Text = " "
                        End With
                    Next
                Else
                    With .Cell(i, 1)
                        .Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
                        .VerticalAlignment = wdCellAlignVerticalCenter
                        If .Range.Text = EmptyCell Then .Range.Text = " "
                    End With
                    Err.Clear
                End If
            Next
        End With
    Next
    Set Col = Nothing
    Application.ScreenUpdating = True
End Sub

[IrinaNN]

Спасибо огромное! Попробовала на нескольких файлах - работает!!! Спасибо еще раз! Работа облегчится. Потестирую на разных документах.

[IrinaNN]

В процессе работы заметила:

• Не все таблицы выравниваются по центру страницы.
• Границы толщина необходима 0,25 пт, цвет Авто.

Еще хотелось бы добавить:
Высоту строк - минимальную задать. (0 см режим минимум)

Но то, что написано уже очень сильно облегчило работу.
СПАСИБО большое!

[IrinaNN]

Помогите пожалуйста доработать макрос...

[shanemac51]

возможно так
макрос внутри

[Step_UA]

или так ...

[IrinaNN]

Добрый день! Долгий декрет был) и к сожалению макрос затерли.... а тут файлы тоже недоступны. кто-то сможет помочь?