Значение в буфер

[zhig]

Добрый день! Есть код VBA в Word. В результате его работы некая переменная содержит текст (сумма прописью). Вопрос такой - можно ли текст из этой переменной поместить в буфер обмена?

[Aent]

http://word.mvps.org/FAQs/MacrosVBA/...eClipboard.htm
http://forum.script-coding.info/viewtopic.php?id=4324
http://www.tek-tips.com/viewthread.c...1173511&page=1

[viter.alex]

Может быть существующий алгоритм работы макроса и не позволит такое делать, но, поскольку работаем в Word, то можно сделать так:

With Selection
  .Collapse
  .Text = "Значение вашей переменной"
  .Cut
End With

Добавлено позже
Для полноты добавлю вариант с использованием функций WinAPI

Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function SetClipboardData Lib "user32" (ByVal wFormat As Long, ByVal hMem As Long) As Long
Private Declare Function EmptyClipboard Lib "user32" () As Long

Private Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)

Private Const CF_TEXT = 1
Private hMemory As Long
Private lpMemory As Long
Private retval As Variant

Public Sub CopyTextToClipboard(ByVal sText As String)
  
  sText = sText & Chr(0)
  hMemory = GlobalAlloc(0, Len(sText) + 1)
  If hMemory <> 0 Then
    lpMemory = GlobalLock(hMemory)
    If lpMemory <> 0 Then
      CopyMemory ByVal lpMemory, ByVal sText, Len(sText) + 1
      retval = GlobalUnlock(hMemory)
      If OpenClipboard(0&) <> 0 Then
        If EmptyClipboard() <> 0 Then
          If SetClipboardData(CF_TEXT, hMemory) = 0 Then _
            MsgBox "Не удалось скопировать «" & sText & "» в буфер обмена", vbCritical + vbOKOnly, "Копировать строку в буфер"
        End If
        CloseClipboard
      End If 'OpenClipboard
    End If 'lpMemory
  End If 'hMemory
End Sub

Этот код лучше всего поместить в отдельный модуль, а использовать так:

CopyTextToClipboard "Ваша переменная"

[zhig]

Большое спасибо! Все работает!!!