быстрый очень быстрый переход в документе

[Окоча Юра]

Знатоки, если не трудно, у себя в документах часто в начале нужных абзацов я вставляю закладки, а потом когда мне нужно перейти в определенную часть документа, я нажимаю ctrl+G - выбираю далее нужную закладку-нажимаю ПЕРЕЙТИ и перемещаюсь в нужную часть докумена - а потом еще нажимаю Esc...
набираю текст я 10 пальцами, ну слишком долго это....
Вот и созрела мысль... можно ли, чтобы набрав в любом месте документа название закладки и нажав макрос, я перешел в нужную закладку, а ранее набранный текст автоматом был бы удален...посмотрите еще приложеный файл...

[forumWord]

Вот такое придумал:

Sub Макрос3()
Dim vИмяЗакладки As String
metka:
    vИмяЗакладки = InputBox("Введите имя закладки")
    If vИмяЗакладки = "" Then Exit Sub
    If ActiveDocument.Bookmarks.Exists(vИмяЗакладки) = False Then
        MsgBox "Неправильно указано имя закладки"
        GoTo metka
    End If
    Selection.GoTo What:=wdGoToBookmark, Name:=vИмяЗакладки
End Sub

[forumWord]

Вот такой ещё вариант. Печатаешь имя закладки, а затем запускаешь марос:

Sub Макрос4()
Dim vИмяЗакладки As String
vИмяЗакладки = Selection.Words(1).Previous.Words(1)
If ActiveDocument.Bookmarks.Exists(vИмяЗакладки) = True Then
    Selection.Words(1).Previous.Words(1).Delete
    Selection.GoTo What:=wdGoToBookmark, Name:=vИмяЗакладки
Else
    MsgBox "Такой закладки нет"
End If
End Sub

[forumWord]

При использовании этого кода, надо сначала поставить пробел, затем напечатать имя закладки, а затем запустить макрос. Этот код создан для случаев, когда в имени закладки встречается символ "_":

Sub Макрос6()
Dim vИмяЗакладки As String
Do While InStr(Selection.Text, " ") = 0
    Selection.MoveLeft unit:=wdWord, Extend:=wdExtend
Loop
vИмяЗакладки = Trim(Selection.Text)
If ActiveDocument.Bookmarks.Exists(vИмяЗакладки) = True Then
    Selection.Delete
    Selection.GoTo What:=wdGoToBookmark, Name:=vИмяЗакладки
Else
    MsgBox "Такой закладки нет"
End If
End Sub

[Окоча Юра]

Спасибо, долго добивался этих макросов...оба макроса хороши...если можно - чтобы в первом макросе при вводе закладки я попадал в начало закладки, а не чтобы она выделялась...
Что касается второго макроса: есть у меня, например в документе предложение: "Украина - наша родина", так вот ставлю курсор перед словом "родина", далее ввожу название закладки, например "аа" , получается "аародина" потом нажимаю макрос и попадаю в начало нужной закладки, при этом сочетание "аа" удаляется)..

[forumWord]

Окоча Юра, нужно пробел ставить перед вставкой имени закладки. Лучше используйте третий код.

[Окоча Юра]

я понял..спасибо за 3-ий макрос...если можно в 1 и 3 макросе сделать чтобы когда я нажму макрос я переходил в начало нужной закладки (тоисть был активным пробел перед этой закладкой)..

[forumWord]

Окоча Юра, вот это

Selection.MoveLeft

надо поместить после

Selection.GoTo What:=wdGoToBookmark, Name:=vИмяЗакладки

[Вождь]

Развил идею (см. комментарии):

Public Sub Bookmark_TypedGo()
' переход к закладке по имени набранному в документе
' - если выбран текст, то считаем его именем
' - ничего не выбрано, то имя перед курсором,
'   начиная с начала абзаца или заданного символа

Const c_StartChars$ = " >" ' набор символов начала закладки

Dim R As Range
Dim N$
Dim L&
    
    ' область имени закладки
    Set R = Selection.Range
    If R.Start < R.End Then
        ' уже выбрана
        N = R.Text ' имя
    Else
        ' перед курсором
        L = R.Paragraphs.First.Range.Start - R.Start
        If R.MoveStartUntil(Cset:=c_StartChars, Count:=L) < 0 Then
            N = R.Text ' имя
            R.MoveStart Unit:=Word.wdCharacter, Count:=-1
        Else
            R.MoveStart Unit:=Word.wdCharacter, Count:=L
            N = R.Text ' имя
        End If
    End If
    N = Trim$(N) ' чистим имя
    
    ' ищем закладку
    If ActiveDocument.Bookmarks.Exists(N) <> True Then
        ' нет закдаки
        StatusBar = "Нет закладки c именем """ & N & """"
    Else
        ' удаляем имя
        L = R.Characters.Count
        R.Collapse Direction:=Word.wdCollapseStart
        R.Delete Unit:=Word.wdCharacter, Count:=L
        ' переход к закладке
        ActiveDocument.Bookmarks(N).Range.Select
        Selection.Collapse Direction:=Word.wdCollapseStart
    End If
    
End Sub

[forumWord]

при этом сочетание "аа" удаляется)..

у меня есть защита в коде от удаления нужного:

ActiveDocument.Bookmarks.Exists(vИмяЗакладки) = True

Не может ничего удалится, если не является именем закладки. Значит есть такая закладка "аародина".

Да, и получается, что и перед и после (если имя закладки не является последним словом в абзаце) должны быть пробелы.