Выделение ячеек с переменными индексами

[layriona]

У меня есть код: Код:

Sub raschet() 
    Dim n As Integer 
    Dim i As Integer 
    n = Range("B4") 
    Range("B8:B10").Select 
    Selection.NumberFormat = "### ### ### ###" 
    For i = 3 To n + 2 
        Cells(7, i) = i - 2 
        Cells(8, i) = Range("B1") 
        Cells(9, i) = Range("B2") 
        Cells(10, i) = Range("B1") - Range("B2") 
        
        ActiveCell.Offset(0, 1).Select 
        Selection.NumberFormat = "### ### ### ###" 
        ActiveCell.Value = (ActiveCell.Value * 1000) 
        
    Next      
End Sub

Я не очень понимаю, почему выделяется в цикле одна ячейка со сдвигом направо, а не все три ячейки, со сдвигом направо. Ведь изначально были выделены три ячейки: Range("B8:B10").Select.
И можно ли как-то по-другому, проще выделить все ячейки с переменным индексом, чтобы потом их все сразу отформатировать?

[EducatedFool]

1. Чтобы выделения ячеек смещалось, надо делать новое выделение относительно прежнего выделения, а не актичной ячейки.
Замените ActiveCell.Offset(0, 1).Select
на Selection.Offset(0, 1).Select

2. Выделять ячейки вообще не требуется.
Без выделения - проще и быстрее:

Sub raschet()
    Dim n As Integer, i As Integer
    n = Range("B4")
    Range("B8:B10").NumberFormat = "### ### ### ###"
    For i = 3 To n + 2
        Cells(7, i) = i - 2
        Cells(8, i) = Range("B1") * 1000
        Cells(9, i) = Range("B2")
        Cells(10, i) = Range("B1") - Range("B2")
    Next
    Range("c8").Resize(3, n).NumberFormat = "### ### ### ###"
    Range("c8").Resize(3, n).Interior.Color = vbGreen
End Sub

3. Можно обойтись без циклов:

Sub raschet()
    Dim n As Integer:    n = [B4]
    
    Range("c7").Resize(1, n).Value = "=column()-2"
    Range("c8").Resize(1, n).Value = "=$B$1*1000"
    Range("c9").Resize(1, n).Value = "=$B$2"
    Range("c10").Resize(1, n).Value = "=$B$1-$B$2"
    
    With Range("c8").Resize(3, n)
        .NumberFormat = "### ### ### ###" ' формат ячеек
        .Interior.Color = vbGreen ' заливка
        .Value = .Value ' если надо заменить формулы значениями
    End With
End Sub

Пример в файле: http://excelvba.ru/XL_Files/Sample__...__11-00-07.zip

[alex77755]

Dim R As Range
  Set R = Union(Range(Cells(1, 6), Cells(2, 8)), _
  Range(Cells(5, 6), Cells(8, 10)), _
  Range(Cells(12, 1), Cells(15, 6)))
 R.NumberFormat = "### ### ### ###"
 R.Interior.Color = vbGreen