Помогите с последовательностью

[==Terman==]

Дана произвольная последовательность А1:А10, в в столбце В надо вычилить разность А2-А1 и так далее. В С1- если все получившиеся числа в столбце В положительные то "последовательность возрастающая", если отрицательные то "убывающая"., а если есть и подожительные и отрицательные, то "смешанная".
Помогите пожалуйста!

[SAS888]

Как нужно решать задачу? Формулами? VBA?

[mc-black]

А если в столбце "C" встречаются нули, то возможны варианты "неубывающая" (нули и положительные) и "невозрастающая" (нули и отрицательные). Так, по-моему, тоже могут классифицироваться последовательности. Или последовательности с нулями считать также "смешанными"?

[mc-black]

Я решил двумя способами. Второй расширенный вариант получается при раскомментировании 6 строк кода в конце процедуры Sequence (в указанном месте). Процедура DeterminateSequence нужна для указания листа, на котором надо обработать последовательность. Последовательность на листе может быть любой длины, главное, чтобы она начиналась с "A1" и содержала хотя бы 2 элемента.

Option Explicit

Sub DeterminateSequence()
    Call Sequence(ThisWorkbook.Worksheets(1))
End Sub

Private Sub Sequence(wsh As Worksheet)
    Dim i As Long
    Dim n As Long
    Dim cntAsc As Long
    Dim cntDsc As Long
    Dim cntZer As Long
    
    ' Заполнение столбца "B" разницами элементов последовательности
    i = 1
    Do While Not wsh.Cells(i + 1, 1).Value = Empty
        wsh.Cells(i, 2).Value = wsh.Cells(i + 1, 1).Value - wsh.Cells(i, 1).Value
        i = i + 1
    Loop
    
    ' Подсчет в столбце "B" числа положительных, отрицательных и нулевых значений
    n = i - 1
    cntAsc = 0
    cntDsc = 0
    cntZer = 0
    For i = 1 To n
        If wsh.Cells(i, 2).Value > 0 Then
            cntAsc = cntAsc + 1
        ElseIf wsh.Cells(i, 2).Value < 0 Then
            cntDsc = cntDsc + 1
        Else
            cntZer = cntZer + 1
        End If
    Next i
    
    ' Выбор типа последовательности судя по значениям счетчиков
    If cntAsc = n Then
        wsh.Cells(1, 3).Value = "возрастающая последовательность"
    ElseIf cntDsc = n Then
        wsh.Cells(1, 3).Value = "убывающая последовательность"
'    Раскомментировать строки ниже для расширенного решения задачи
'    Или удалить совсем, как ненужную часть задачи
'    ElseIf cntAsc + cntZer = n Then
'        wsh.Cells(1, 3).Value = "неубывающая последовательность"
'    ElseIf cntDsc + cntZer = n Then
'        wsh.Cells(1, 3).Value = "невозрастающая последовательность"
'    ElseIf cntZer = n Then
'        wsh.Cells(1, 3).Value = "константная последовательность"
    Else
        wsh.Cells(1, 3).Value = "Смешанная последовательность"
    End If
End Sub

[==Terman==]

Мне надо решить эту задачу формулой в Екселе. А в с1 получить получить результат. Подскажите пожалуйста как надо через функцию "если"

Я вложил файл

[pivas]

Попробуйте так: