добавление строки в Listbox массивом

[Composter]

Доброго времени суток уважаемые форумчане, есть несколько вопросов
хочу сделать макрос в userform,который добавлял бы из userform текущие значения в listbox .столкнулся с тем что больше 10 столбцов вручную не получится ввести.поэтому пытаюсь передать с помощью массива.
1)можно ли добавить массив в новую строчку listbox не заменяя листбокс, а то я знаю только такой способ

    ListBox4.List = array1

2)попробовал создать динамический массив и потом переопределять его ,но вылезает ошибка при повторном переопределении массива subscript out of range
в заголовке userform задаю

Dim array1() As String

а дальше в коде userform

Private Sub CommandButton2_Click()

ReDim Preserve array1(nomer_po_spisku, 13) As String

    array1(nomer_po_spisku, 0) = (nomer_po_spisku + 1)
    array1(nomer_po_spisku, 1) = TextBox1.Text
    array1(nomer_po_spisku, 2) = TextBox14.Text
    array1(nomer_po_spisku, 3) = TextBox12.Text
    If Val(TextBox10.Text) = 0 Then
        array1(nomer_po_spisku, 4) = TextBox9.Text
        array1(nomer_po_spisku, 5) = "-"
        array1(nomer_po_spisku, 6) = "-"
        Else
            array1(nomer_po_spisku, 4) = "-"
            array1(nomer_po_spisku, 5) = TextBox9.Text
            array1(nomer_po_spisku, 6) = TextBox10.Text
    End If
    array1(nomer_po_spisku, 7) = TextBox19.Text
    array1(nomer_po_spisku, 8) = R
    array1(nomer_po_spisku, 9) = pot_po_dline
    array1(nomer_po_spisku, 10) = P_din
    array1(nomer_po_spisku, 11) = TextBox11.Text
    array1(nomer_po_spisku, 12) = pot_na_mestn
    array1(nomer_po_spisku, 13) = pot_na_mestn + pot_po_dline
    nomer_po_spisku = nomer_po_spisku + 1
    
    ListBox4.List = array1
end sub

что я делаю не так?

[R Dmitry]

Private Sub CommandButton2_Click()
With ListBox1
.ColumnCount = 13
.AddItem
.List(.ListCount - 1, 1) = "1"
.List(.ListCount - 1, 2) = "2"
.List(.ListCount - 1, 3) = "3"
'..........................................
.List(.ListCount - 1, 9) = "9"
End With
End Sub

___________________________________ _____________-
у вас надо изменить

 ReDim Preserve array1(13, nomer_po_spisku) As String

и так весь массив изменить, т.е поменять местами, менять можно только последнюю размерность массива

[R Dmitry]

да и...nomer_po_spisku глобальная переменная??

[Composter]

в шапке формы стоит

Dim nomer_po_spisku As Integer

а вашем предложенном варианте не получается больше 10 столбцов
а если массив сделать array1(13,nomer_po_spisku) и потом переопределять,то все работает только запись идет в столбцы, а мне нужно что бы в строку

[Composter]

нашел выход из ситуации
в заголовке формы

Dim array1(100, 13) As String

в инициализации

Private Sub UserForm_Initialize()
nomer_po_spisku = 0
end sub

Private Sub CommandButton2_Click()
If nomer_po_spisku > UBound(array1, 1) Then
    MsgBox ("больше нельзя добавить строк")
    Exit Sub
End If
    array1(nomer_po_spisku, 0) = (nomer_po_spisku + 1)
    array1(nomer_po_spisku, 1) = TextBox1.Text
    array1(nomer_po_spisku, 2) = TextBox14.Text
    array1(nomer_po_spisku, 3) = TextBox12.Text
    If Val(TextBox10.Text) = 0 Then
        array1(nomer_po_spisku, 4) = TextBox9.Text
        array1(nomer_po_spisku, 5) = "-"
        array1(nomer_po_spisku, 6) = "-"
        Else
            array1(nomer_po_spisku, 4) = "-"
            array1(nomer_po_spisku, 5) = TextBox9.Text
            array1(nomer_po_spisku, 6) = TextBox10.Text
    End If
    array1(nomer_po_spisku, 7) = TextBox19.Text
    array1(nomer_po_spisku, 8) = R
    array1(nomer_po_spisku, 9) = pot_po_dline
    array1(nomer_po_spisku, 10) = P_din
    array1(nomer_po_spisku, 11) = TextBox11.Text
    array1(nomer_po_spisku, 12) = pot_na_mestn
    array1(nomer_po_spisku, 13) = pot_na_mestn + pot_po_dline

    ListBox4.List = array1
    
    nomer_po_spisku = nomer_po_spisku + 1
End Sub

а не заполненые члены массива не добавляются в listbox

[R Dmitry]

Сообщение от Composter

в шапке формы стоит

а вашем предложенном варианте не получается больше 10 столбцов
а если массив сделать array1(13,nomer_po_spisku) и потом переопределять,то все работает только запись идет в столбцы, а мне нужно что бы в строку

ListBox4.List = application.transpose(array1)

[Composter]

спасибо,большое.заработало!!!

[Composter]

а подскажите почему при

ListBox4.List = Application.Transpose(array1)

размерность массивов получается одинаковая
,а при

 array1 = Application.Transpose(ListBox4.List)

размерность массива array1 получается на 1 больше чем размерность массива ListBox4.List ?

[Composter]

разообрался,если задать массив

Dim array1(1 To 15, 1 To nomer_po_spisku) As Variant

транспонирование в listbox и обратно происходит корректно