Перенос форм из Экселя в Ворд

[Nash1]

С сохранением форматирования средствами Ворд. Ячейки в Экселе мелкие, поэтому при копировании и вставке сбиваются все размеры. Также из-за того, что в строке по 40 мелких ячеек невозможно вбивать данные на лиц, которые создают фирмы. А нам для нормальной работы - чтобы вбивать данные - нужны формы в Ворде 2003. Речь идёт о формах для регистрации фирм нового образца, которые вступили в действие с 1 июля 2009. ссылочка на формы - h**p://www.nalog.ru/index.php?topic=forms_gosreg312fz

[viter.alex]

Могу перенести в Word вручную. Пишите. Контакты в профиле

[EducatedFool]

Сделал макрос, который находит в книгах Excel ячейки, требующие объединения, и объединяет их.

На скриншоте обработанные ячейки помечены цветом:



Теперь можно работать с этими формами и в Excel (без ручного переноса в Word)

Результаты обработки:

На листе стр.1 произведено 17 объединений ячеек
На листе стр.2_Лист А произведено 20 объединений ячеек
На листе стр.3_Лист Б произведено 22 объединений ячеек
На листе стр.4_Лист В произведено 2 объединений ячеек
На листе стр.5_Лист Г произведено 11 объединений ячеек
На листе стр.6_Лист Г(2) произведено 48 объединений ячеек
На листе стр.7_Лист Г (3) произведено 16 объединений ячеек
На листе стр.8_Лист Д произведено 26 объединений ячеек
На листе стр.9_Лист Е произведено 26 объединений ячеек
На листе стр.10_Лист Ж произведено 2 объединений ячеек
На листе стр.11_Лист З произведено 2 объединений ячеек
На листе стр.12_Лист И произведено 1 объединений ячеек
На листе стр.13_Лист К произведено 36 объединений ячеек
На листе стр.14_Лист К(2) произведено 4 объединений ячеек
На листе стр.15_Лист Л произведено 39 объединений ячеек
На листе стр.16_Лист Л(2) произведено 11 объединений ячеек
На листе стр.17_Лист М произведено 17 объединений ячеек
На листе стр.18_Лист М(2) произведено 42 объединений ячеек
На листе стр.19_Лист М(3) произведено 11 объединений ячеек
На листе стр.20_Лист Н произведено 40 объединений ячеек
На листе стр.21_Лист Н(2) произведено 15 объединений ячеек
На листе стр.22_Лист Н(3) произведено 2 объединений ячеек

[EducatedFool]

Вот весь код (может, кому пригодится для обработки ужасно оформленных шаблонов документов из налогового ведомства)

Sub ОбъединениеЯчеек() ' основной макрос
    Application.DisplayAlerts = False: On Error Resume Next
    Dim sh As Worksheet: Application.ScreenUpdating = False
    For Each sh In ActiveWorkbook.Worksheets
        ОбъединениеЯчеекЛиста sh: DoEvents
    Next sh
    Application.DisplayAlerts = True
End Sub

Sub ОбъединениеЯчеекЛиста(ByRef sh As Worksheet)
    Dim cell As Range, lcell As Range
    Dim s As Range, a As Range, ce As Range: n = 0
    For Each cell In sh.UsedRange.Cells
        If НачалоКлетки(cell) Then
            Set lcell = ПоследняяЯчейкаКлетки(cell)
            If Not lcell Is Nothing Then
                Set s = sh.Range(cell, lcell): txt = ""
                For Each ce In s: txt = txt & ce.Text: Next ce
                txt = WorksheetFunction.Trim(txt):    'Debug.Print s.Address, s.Cells.Count, txt
                s.Merge: s.Cells(1) = txt: n = n + 1:    's.Interior.Color = vbGreen
            End If
        End If
    Next cell
    Debug.Print "На листе " & sh.Name & " произведено " & n & " объединений ячеек"
End Sub

Function НачалоКлетки(ByRef cell As Range) As Boolean
    НачалоКлетки = cell.Borders(xlEdgeTop).LineStyle <> xlNone And cell.Borders(xlEdgeLeft).LineStyle <> xlNone
End Function

Function КонецСтроки(ByRef cell As Range) As Boolean
    КонецСтроки = cell.Borders(xlEdgeRight).LineStyle <> xlNone And cell.Borders(xlEdgeBottom).LineStyle <> xlNone
End Function

Function ПоследняяЯчейкаКлетки(ByRef cell As Range) As Range
    If cell.MergeCells Then Exit Function
    Dim lcell As Range: Set lcell = cell
    While Not Intersect(lcell, cell.Parent.UsedRange) Is Nothing
        If КонецСтроки(lcell) Then Set ПоследняяЯчейкаКлетки = lcell: Exit Function
        Set lcell = lcell.Next
    Wend
End Function

Результат обработки - во вложении:
(обратите внимание, что порой попадается лишний текст, как, например, на листе стр.3_Лист Б формы p13001_260609.xls в ячейках i41:i43 - его не видно, но при объединении ячеек он станет виден)

Макрос далеко не самый быстрый из возможных, поэтому на обработку одного файла уходит 10-30 секунд.

[Sebastian]

Уважаемый Educated Fool, а Ваш макрос обрабатывает только эти документы, или его можно применять к разным другим, созданным любимыми ФНСниками?

[EducatedFool]

макрос обрабатывает только эти документы, или его можно применять к разным другим, созданным любимыми ФНСниками?

Не проверял, но, скорее всего, подойдёт к любым (где все столбцы узкие и одинаковые по ширине)

Почему-то им было лень оформить документы как надо (к примеру, из 19 полей 15 могут состоять из объединённых ячеек, а 4 оставшиеся - из 5 мелких ячеек каждое)

Как я уже указывал, присутствуют неточности обработки:

порой попадается лишний текст, как, например, на листе стр.3_Лист Б формы p13001_260609.xls в ячейках i41:i43 - его не видно, но при объединении ячеек он станет виден

В этом случае придётся подчистить несколько ячеек вручную.
Но в этом виноват не макрос, а кривые руки сотрудников ФНС.

Если есть возможность - проверьте макрос на других документах, и сообщите результат.