Печать цветных и черно-белых страниц на разные принтеры

[rain_day]

Знаешь, если принцип работает и дело действительно в том что ты говоришь, почему бы нам не разделить конечную цель на 2 макроса? Одну кнопь нажал - пошли чб страницы. Другую кнопь нажал - пошли цв страницы. Возможно, это даже удобнее будет в каких-то случаях. Щас даже попробую поколупать макрос, хотя вряд ли чего выдет у меня с первого раза
А! Еще заметил, что описаный мною результат получен именно на большом документе. А создав док из нескольких страниц для теста, там макрос вообще ни чего не делает. Ставит в очередь на печать и сразу убирает

или формирование списка страниц на принтеры сделать не одним оператором, а двумя. Т.е.

Если есть рис. то добавляем в цв список, в противном случае - ничего. Конец

Если нет рис. то добавляем в чб список, в противном случае - ничего. Конец

как-то так по-русски

[viter.alex]

Попробуем проверять BackgroundPrintingStatus

Sub SeparatePrint()
  Const PRINTER_BW = "Принтер чернобелой печати"
  Const PRINTER_COLOR = "Принтер цветной печати"
  Dim sBWPages As String 'Строка для номеров страниц на ч\б печать
  Dim sColorPages As String 'Строка для номеров страниц на цветную печать
  Dim oDoc As Document: Set oDoc = ActiveDocument 'Документ, который нужно распечатать
  Dim nPage As Long: nPage = 1 'Номер страницы
  Dim oPageRng As Range 'Диапазон отдельной страницы
  Dim nPages As Long: nPages = oDoc.Range.ComputeStatistics(wdStatisticPages) 'Количество страниц в документе
  Do
    'Переходим в начало отдельной страницы
    Set oPageRng = oDoc.Range.GoTo(wdGoToPage, wdGoToAbsolute, nPage)
    'Растягиваем диапазон на всю страницу
    If nPage < nPages Then
      oPageRng.SetRange oPageRng.Start, oDoc.Range.GoTo(wdGoToPage, wdGoToAbsolute, nPage + 1).Start
    Else
      oPageRng.SetRange oPageRng.Start, oDoc.Range.End
    End If
    
    If oPageRng.InlineShapes.Count = 0 And oPageRng.ShapeRange.Count = 0 Then 'Если нет рисунков
      sBWPages = sBWPages & nPage & "," 'Добавляем в список страниц для печати на ч\б принтер
    Else 'Если есть рисунки
      sColorPages = sColorPages & nPage & "," 'Добавляем в список страниц для печати на цветной принтер
    End If
    nPage = nPage + 1
  Loop While nPage <= nPages
  sBWPages = Left(sBWPages, Len(sBWPages) - 1)
  sColorPages = Left(sColorPages, Len(sColorPages) - 1)
  ActivePrinter = PRINTER_BW 'Задаем ч\б принтер
  'Отправляем на печать ч\б страницы
  oDoc.PrintOut Range:=wdPrintRangeOfPages, Pages:=sBWPages
'------------------------------------------------------------------
  'Делаем задержку, пока задание на печать ещё не выполнено
  Do
    DoEvents
  Loop While Application.BackgroundPrintingStatus > 0
'------------------------------------------------------------------
  ActivePrinter = PRINTER_COLOR 'Задаем цветной принтер
  'Отправляем на печать цветные страницы
  oDoc.PrintOut Range:=wdPrintRangeOfPages, Pages:=sColorPages
End Sub

[rain_day]

Прогресс определённо есть! У меня теперь оба принтера напечатали только чб. А может после формирования списка на чб сразу отправлять его на печать? А потом формировать список цв и опять отправлять

[viter.alex]

Ё-моё, и ты ничего не увидел!
Посмотри внимательно в код, какая переменная отправляется на цветную печать? Код пока исправлять не буду

[rain_day]

ТЫ ГЕНИИИИИИЙ!!!!
Спасибо огромное, побежал счастливый тестировать в рабочем процессе!

А мне еще такая мысля пришла. Возможно еще при этом проверять графические объекты цветны или чб? И если чб, то пришивать их к списку чб

[viter.alex]

Дай пример документа, где есть цветные и ч\б рисунки.

[rain_day]

Прилагаю. Но его пришлось сохранить в формате doc вместо docx

[viter.alex]

С наскока не получилось. Дело в том, что у объекта InlineShape, каковыми являются рисунки в предоставленном документе, есть свойство PictureFormat.ColorType. Но оно покажет, что рисунок ч\б только если к нему применить команду Перекрасить→Черно-белое. Если же этого не делать, тогда никак не определить.
Вернее, чистым VBA никак, но есть еще функции WinAPI, которые это могут. Но это совсем другая история

[rain_day]

А как пришить к данному макросу хотя бы такую команду? Может и такой способ приживётся. Всё легче, чем выписывать номера страниц на листик

[viter.alex]

Какую команду?