Как корректно завершить цикл?

[Iren]

Есть полностью рабочий код, но когда удаляются в листе все строки содержащие слово "поврежденная" то команда cells.find..........activate не может активировать то, чего нет, так вот как избежать ошибки и что сделать, чтобы этот код удалял строки, содержащие слово поврежденная и потом когда уже не находил это слово то просто останавливался а не выдавал ошибку?

 Sheets("Сканеры").Select
     Range("H1").Select
  For i = 1 To Range("H1").SpecialCells(xlLastCell).Row
Cells.Find(What:="поврежденная", After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False) _
        .Activate
       i = ActiveCell.Row
 Rows(i).Select
Selection.Delete Shift:=xlUp
Next i

[Iren]

был еще такой вариант но он ищет ячейки которые равны слову поврежжденная а в моем случае надо искать содержит слово поврежденная. может тут подскажете какие параметры прописать * и % уже пыталась вписать. результатов ноль

 For i = 1 To Range("C1").SpecialCells(xlLastCell).Row
   If Sheets("Сканеры").Cells(i, 3).Value = "поврежденная" Then Sheets("Сканеры").Rows(i).Delete
   Next

[Iren]

и был такой вариант (с сайта взято)- привожу без своих изменений т.к у меня там особо ничего не получилось. вот может кто подскажет может этот как то до ума довести

Dim FirstMatch As String

FirstMatch = "" ' пока ничего еще не найдено, см. далее
For Each W In Worksheets ' букв. "для каждого из листов книги"
' ищем первое вхождение "zzz", параметры в хелпе есть
 Set R = W.Cells.Find(What:="zzz", _
                      After:=ActiveCell, _
                      LookIn:=xlValues, _
                      LookAt:=xlPart, _
                      SearchOrder:=xlByRows, _
                      SearchDirection:=xlNext, _
                      MatchCase:=False)
' пока что-то найдено
 Do While (Not R Is Nothing)
' ***** здесь действия над найденными ячейками *****
' адрес ячейки: строка=R.Row, колонка=R.Column

' *****
' запомнить первый результат на листе
  If FirstMatch = "" Then FirstMatch = R.Address
' поискать еще на этом же листе
  Set R = W.Cells.FindNext(R)
' есди нашли то, что уже было, то выход
  If FirstMatch = R.Address Then GoTo NextSheet
 Loop
NextSheet:
 FirstMatch = "" ' обнулить первый результат
Next W ' следующий лист

[pashulka]

With Worksheets("Сканеры").UsedRange
     Set iCell = .Find(What:="поврежденная", LookIn:=xlValues, LookAt:=xlPart)
     Do Until iCell Is Nothing
        iCell.EntireRow.Delete
        Set iCell = .FindNext
     Loop
End With

[Iren]

о спасибо большущее оно работает.
Do Until iCell Is Nothing
я представляла что должна быть подобная строчка, но как она звучит не имела понятия