-> макрос для Word на Visual Basic

[NewFire]

Доброго времени суток. Прошу помочь в следующем вопросе.

Нужно написать макрос последовательной нумерации всех формул в тексте. Формулы оформить по стандартам, т.е. формула - по центру, номер формулы - по правому краю. Номера формул выделить жирным шрифтом. Нумерация формул в тексте сквозная. Ваши предложения...

[viter.alex]

Документ с формулами в студию! (хотя бы часть документа)
Знаю 3 (три) сравнительно простых способа это сделать.

Добавлено позже
Я так понимаю, что вы хотите получить нечто, похожее на то, что в приложении?

[NewFire]

Да, посмотрел приложение, совершенно верно. Чем проше тем лучше.

[viter.alex]

Видно, примера документа я от вас не дождусь. Хорошо, даю макрос так, как я его представляю.

Sub NumberEquation()
  Dim oIShape As InlineShape
  Dim oRng As Range
  For Each oIShape In ActiveDocument.InlineShapes
    If oIShape.OLEFormat.ClassType = "Equation.3" Then
      Set oRng = oIShape.Range
      With oRng.ParagraphFormat
        .SpaceAfterAuto = False: .SpaceBeforeAuto = False
        .FirstLineIndent = 0
        .TabStops.ClearAll
        .TabStops.Add Position:=(ActiveDocument.PageSetup.PageWidth - ActiveDocument.PageSetup.LeftMargin - ActiveDocument.PageSetup.RightMargin - .LeftIndent - .RightIndent) / 2, _
                      Alignment:=wdAlignTabCenter, Leader:=wdTabLeaderSpaces
        .TabStops.Add Position:=(ActiveDocument.PageSetup.PageWidth - ActiveDocument.PageSetup.LeftMargin - ActiveDocument.PageSetup.RightMargin - .LeftIndent - .RightIndent), _
                      Alignment:=wdAlignTabRight, Leader:=wdTabLeaderSpaces
      End With
      With oRng
        .InsertBefore vbTab
        .Collapse wdCollapseEnd
        .InsertParagraphAfter
        .Select
        With Selection
          .InsertStyleSeparator
          .Font.Bold = True
          .TypeText vbTab & "("
          .Fields.Add .Range, wdFieldEmpty, "SEQ formula", True
          .TypeText ")"
        End With
      End With
    End If
  Next oIShape
End Sub

После применения макроса формулы в документе должны выглядеть так, как в примере из моего предыдущего поста. Если какую-либо формулу вы удалите или, наоборот, добавите, то нумерация изменится автоматически. Только добавлять нужно, скопировав строку со старой формулой и номером в новое место.

[NewFire]

Большое спасибо, работает прямо так как и хотел.

[viter.alex]

Пожалуйста. Одно замечание. Этот макрос я совсем чуть-чуть переделал из того, что у меня было. А был у меня макрос, который вставлял в документ формулу с нумерацией.
Можно проделать и обратный путь: из приведенного макроса, который нумерует ненумерованные формулы, получить макрос, который вставляет формулу с нумерацией.

[VIDI]

Всем привет! Viter.alex пытался добавить кнопку к твоему макросу, но связать код и кнопку не получилось. Как это сделать?:-)

[viter.alex]

Сообщение от VIDI

Всем привет! Viter.alex пытался добавить кнопку к твоему макросу, но связать код и кнопку не получилось. Как это сделать?:-)

Какой офис?

[VIDI]

Офис 2003!

[viter.alex]

На панели инструментов кликнуть правой кнопкой мыши и выбрать «Настройка». Перейти на вкладку «Команды» и в списке «Категории» выбрать пункт «Макросы».

При этом в правом списке «Команды» появятся все макросы, доступные для документа, например Normal.ThisDocument.NumberEquation. Это означает, что макрос с именем NumberEquation записан во встроенный модуль ThisDocument шаблона Normal.dot. Хватаете этот макрос мышкой и тащите на удобное для вас место на панели инструментов.

После того, как перетащили, правый клик по этой кнопке и можете выбрать название для кнопки, рисунок и прочее.