Как преобразовать значение полей в документе в текст

[Traum]

Я сам кажется разобрался как обновлять поля и переводить их в текст

чем плохи методы:

Ctrl + A; F9; Ctrl + Shift + F9
ActiveDocument.Fields.Unlink
ActiveDocument.Fields.Update

Тем, что они

• не воздействуют на поля в надписях, которые могут располагаться как сами по себе, так и внутри полотна.
• отлинковывывают все поля, включая те которые не нужно. Например, поля формул Mathtype или иные вставленные объекты, которые часто не нужно отлинковывать

Часто обновлять и переводить в текст имеет смысл только поля SEQ и REF (включая такие поля в надписях внутри полотен). Ниже представлены 2 макроса для выполнения данной задачи.


Для обновления полей типа SEQ и REF используется макрос DocumentUpdateFields
Для обновления и перевода в текст полей типа SEQ и REF используется макрос DocumentUnlinkFields

Сначала обновляются только поля SEQ, а лишь затем REF, иначе некоторые REF поля могут быть обновлены до обновления поля SEQ, на которое они ссылаются и получат неверное значение

' field tasks
Const ftUpdateSeqFields As Integer = 1
Const ftUpdateRefFields As Integer = 2
Const ftUnlinkSeqAndRefFields As Integer = 3

Sub DocumentUpdateFields()
  DocumentHandleFields ftUpdateSeqFields
  DocumentHandleFields ftUpdateRefFields
End Sub

Sub DocumentUnlinkFields()
  DocumentHandleFields ftUpdateSeqFields
  DocumentHandleFields ftUpdateRefFields
  DocumentHandleFields ftUnlinkSeqAndRefFields
End Sub

Private Sub DocumentHandleFields(Task As Integer)
  Dim j As Integer
  HandleFields ActiveDocument.Fields, Task       ' обрабатываем обычные поля в документе
  HandleShapesFields ActiveDocument.Shapes, Task ' обрабатываем поля в самостоятельных фигурах
  j = 1
  Do
    If j > ActiveDocument.Shapes.Count Then
      Exit Do
    End If
    HandleShapesFields ActiveDocument.Shapes(j).CanvasItems, Task ' обрабатываем поля в фигурах внутри полотен
    j = j + 1
  Loop
End Sub

Private Sub HandleShapesFields(Shapes As Shapes, Task As Integer)
  Dim j As Integer
  j = 1
  Do
    If j > Shapes.Count Then
      Exit Do
    End If
    If Shapes(j).TextFrame.HasText Then
      HandleFields Shapes(j).TextFrame.TextRange.Fields, Task
    End If
    j = j + 1
  Loop
End Sub

Private Sub HandleFields(Fields As Fields, Task As Integer)
  Dim i As Integer
  Dim IsSeqField As Boolean
  Dim IsRefField As Boolean
  i = 1
  Do
    If i > Fields.Count Then
      Exit Do
    End If
    IsSeqField = (Fields(i).Code Like "SEQ *")
    IsRefField = (Fields(i).Code Like "REF *")
    Select Case Task
      Case ftUpdateSeqFields
        If IsSeqField Then Fields(i).Update
      Case ftUpdateRefFields
        If IsRefField Then Fields(i).Update
      Case ftUnlinkSeqAndRefFields
        If (IsSeqField Or IsRefField) Then Fields(i).Unlink
    End Select
    i = i + 1
  Loop
End Sub

Буду рад узнать мнение знатоков

[Ципихович Эндрю]

Const ftUpdateSeqFields As Integer = 1
Const ftUpdateRefFields As Integer = 2
Const ftUnlinkSeqAndRefFields As Integer = 3

As Byte не подходит???

[Traum]

As Byte не подходит???

Подойдет и Byte. Но по мне более привычные типы это: integer, real, string. Остальное лишь только в случаях когда стоит вопрос об экономии памяти или строгом соответствии структур данных

[Ципихович Эндрю]

real - что за зверь???

[Traum]

real - это зверь из других языков. Для меня Visual Basic язык новый, поэтому я не все помню. На счет Byte - просто если стоит integer - то это легко воспринимается, а если поставить Byte, то это будет пусть небольшая но дополнительная нагрузка на мозги.