прописать текущую дату

[vostok]

Excel 2003. Срочно! В столбец периодически вписываются разные цифры, надо, чтобы в соседнем столбце напротив цифр прописывалась текущая дата и время, и не обновлялись при открытии, т. е. должно быть видно, когда цифры введены. Помогите, плиз.

[IFRSoff]

Помню кто-то делал тут. Я себе сохранил. Вот так примерно это выглядит. Введите значения в столбец А.

[vostok]

Спасибо большое, очень долго искал этот код, сейчас вставляю в листы, правда, они все запароленные, код не работает на таких, но вчера видел здесь в форуме, что как-бы также кодом можно снять, а потом поставить пароль, буду экспериментировать, не подскажете по теме?
Код (или это макрос?):

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Cells.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("F:F")) Is Nothing Then
With Target(1, 2)
.Value = Now
.EntireColumn.AutoFit
End With
End If
End Sub

Спасибо еще раз!

[alex_r]

Слегка поправил, теперь код отслеживает изменения, даже если больше одной ячейки изменено. Но если, например, изменить весь столбец, то выполнение кода на несколько минут обеспечено. Как можно оптимизировать?

Private Sub Worksheet_Change(ByVal Target As Range)
'If Target.Cells.Count > 5 Then Exit Sub
If Not Intersect(Target, Range("A:A")) Is Nothing Then
For Each cell In Target
With cell(1, 2)
.Value = Now
.EntireColumn.AutoFit
End With
Next
End If
End Sub

[EducatedFool]

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A:A")) Is Nothing Then
        On Error Resume Next
        Application.ScreenUpdating = False
        For Each cell In Intersect(Target, Range("A:A"), Cells.SpecialCells(xlCellTypeConstants)).Cells
            With cell.Next
                .Value = Now
                .EntireColumn.AutoFit
            End With
        Next
    End If
End Sub

А лучше так:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A:A")) Is Nothing Then
        On Error Resume Next: Application.ScreenUpdating = False
        For Each cell In Intersect(Target, Range("A:A"), Cells.SpecialCells(xlCellTypeConstants)).Cells
            cell.Next.Value = Now
        Next
        Range("A:A").EntireColumn.AutoFit
    End If
End Sub

[vostok]

Всем большое спасибо! Подобрал себе какую надо. А с запароленым листом просто сделал: дата пишется в скрытый незащищенный столбец(.EntireColumn.AutoFit пришлось убрать), а с него копируется уже в видимый защищенный.

[Rom1k06]

А можно в начале кода прописать
Unprotect(Пароль)


а в конце кода
Protect(Пароль)

Получится так :
Сначала распаролит лист, внесет изменения, а потом опять запаролит!

[1kach]

Как сделать что бы при внесении данных в строках, автоматически устанавливалась текущая дата в верхней ячейке данного столбца /т.е. если в горизонтально строке данной таблицы есть какая нить цифра, то в самой верхней ячейки данного столбца указывается дата ввода информации

[Teslenko_EA]

Здравствуйте 1kach.
добавьте в код листа подобные строки:

Private Sub Worksheet_Change(ByVal Target As Range)
    Cells(1, Target.Column) = Date
End Sub

Евгений.
P.S.если Вы желаете и в будущем получать ответы на вопросы, создавайте свою "ветку" и это будет правильно.