Перенос данных из ячеек

[gavrylyuk]

Добрый день. Помогите пожалуйста подправить код
Dim x As Range, y As Range, i As Long
Application.ScreenUpdating = False
Sheets("1").Activate
With Sheets("2")
For i = 10 To .Cells(Rows.Count, "A").End(xlUp).Row
Set x = Columns("A").Find(what:=.Cells(i, "A"), LookAt:=xlWhole)
If Not x Is Nothing Then
Set y = Columns("L").Find(what:=.Cells(i, "B"), LookAt:=xlWhole)
If Not y Is Nothing Then Cells(x.Row, y.Column) = .Cells(i, "L")
End If
Next
End With

Этот код ищет на листе 2 совпадение с листом 1 по двум колонкам А и В, и при совпадении записывает значение из листа 2 на лист 1 в соответствующую колонку. А колонка - это имя, а В - дата. Этот код все правильно делает только результат выводит в колонку B, а мне нужно в L.
Помогите пожалуйста
Спасибо

[дмидми]

Опишите, пожалуйста, своими словами подробно: что где ищется, откуда что берётся и что куда пишется.


P.S. Приведённый код никак не может что-то записать в колонку B листа 1:
единственный оператор, который может что-то куда-то записать, запишет в колонку L.


P.P.S. Мелкие придирки

1) Вместо Sheets здесь лучше Worksheets, иначе можешь и не заметить, что пытаешься найти ячейку-строку-etc. на листе диаграммы.

2) Хэлп ёкселя недвусмысленно требует после
Application.ScreenUpdating = False
обязательно ставить
Application.ScreenUpdating = True

3) Опять-таки, в большом (а лучше всего в любом) коде желательно исходить из того, что неизвестно наверняка, какой именно лист активен, - ведь это может быть и лист диаграммы. Поэтому конструкция
With Worksheets("2")
For i = 10 To .Cells(Rows.Count, ...
, которая рассматривает ячейки листа "2", а счётчик строк берёт с "неведомого" активного листа, чревата неприятностями.
Так что лучше перед Rows поставить точку:
....Cells(.Rows.Count,...

Хотя, конечно, бывают случаи, когда работа с неактивным листом невозможна.

4) Прочтите Remarks в хэлпе на Find Method. В инструкции
Set x = Columns("A").Find(...
маловато параметров.

5) После успешного поиска
Set y = Columns("L").Find(...
ячейка y гарантированно находится в колонке L, так что следующий за поиском оператор
If Not y Is Nothing Then Cells(x.Row, y.Column) ...
вполне можно записать как
If Not y Is Nothing Then Cells(x.Row, "L") ...

Получается

Sub gavrylyuk128855()
    Dim x As Range, y As Range, i As Long

    Application.ScreenUpdating = False
    Worksheets("1").Activate ''''
    With Worksheets("2") ''''
    For i = 10 To .Cells(.Rows.Count, "A").End(xlUp).Row ''''
        Set x = Columns("A").Find(what:=.Cells(i, "A") _
            , LookAt:=xlWhole)
        If Not x Is Nothing Then
            Set y = Columns("L").Find(what:=.Cells(i, "B") _
                , LookAt:=xlWhole)
            If Not y Is Nothing Then Cells(x.Row, "L") _
                = .Cells(i, "L") ''''
        End If 'Not x Is Nothing
    Next 'i
    End With 'Worksheets("2")
    Application.ScreenUpdating = True ''''
End Sub

[gavrylyuk]

спасибо єто то что как раз нужно!!!