Как поставить пробел, через 8 знаков

[valerij]

Как поставить пробел, через 8 знаков. В аттаче текстовый файл, сохранить нужно в том же формате
Фрагмент примера:

Исходник
55aa7be91102000000000000000000000000000000000000c40100000000494.........
Результат
55aa7be9 11020000 00000000 00000000 00000000 00000000 c4010000 00004942 ........

Сделал в Word 2003, макросом

Sub Пробел()
For f = 0 To 20000 ' Количество строк
    Selection.MoveRight Unit:=wdCharacter, Count:=8
    Selection.TypeText Text:=" "
    Next
End Sub

[EducatedFool]

Вот тебе макрос:

Sub ОбработкаТекстовогоФайла()
    ' On Error Resume Next
    Dim txt As String, txt2 As String
    Filename = "C:\Рабочий стол\videobios.txt"
    NewFilename = Replace(Filename, ".txt", " - Обработанный.txt")
    'Dim fso As FileSystemObject, ts As TextStream
    Set fso = CreateObject("scripting.filesystemobject")
    Set ts = fso.OpenTextFile(Filename, 1, True): txt = ts.ReadAll: ts.Close
    txt = Replace(txt, Chr(10), "")

    For i = 1 To Len(txt) / 8
        txt2 = txt2 & Mid$(txt, (i - 1) * 8 + 1, 8) & " "
    Next i
    txt2 = Trim(txt2)

    Set ts = fso.CreateTextFile(NewFilename, True)
    ts.Write txt2: ts.Close
End Sub

Не забудь заменить путь к файлу.
В той же папке будет создан файл с именем videobios - Обработанный.txt

[valerij]

Сообщение от EducatedFool

Вот тебе макрос:

Игорь, Супер, Спасибо.
А вордовски, что я сделал, че та врет, местами отделил по семь знаков

[IgorGO]

аналогично, Сделал в Word. Копируем данные в документ Word, запускаем макрос1. Нервно курим минуты 3-4.

Думаю, то что EducatedFool написал, справиться с задачей в 100, а то и в 1000 раз быстрее (за несколько секунд).

Sub Макрос1()
Selection.HomeKey Unit:=wdStory
Макрос2
Selection.WholeStory
Size = Selection.End / 8
Selection.HomeKey Unit:=wdStory
n = 0
Do
If Selection.MoveRight(wdCharacter, 8) < 8 Then Exit Sub
Selection.TypeText Text:=" "
n = n + 1
Application.StatusBar = n & " => " & Format(n / Size, "00.00%")
Loop Until False
End Sub

Sub Макрос2()
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFor matting
With Selection.Find
.Text = "^p"
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
Selection.Find.Execute
Selection.WholeStory
End Sub

А вордовски, что я сделал, че та врет, местами отделил по семь знаков

ничего он не врет, как написано, так и делает. В тексте присутствуют знаки "конец абзаца", а это тоже символ, хоть и специальный

[valerij]

Сообщение от IgorGO

аналогично, Сделал в Word. Копируем данные в документ Word, запускаем макрос1. Нервно курим минуты 3-4. В тексте присутствуют знаки "конец абзаца", а это тоже символ, хоть и специальный

Та по времени, < пол минуты, я на угад поставил 20000 в For.
Игоря макрос, мгновенно
А де ты там нашел, знаки "конец абзаца"?
А врет, посмотри второе значение

c4010000 0000494 24da1000

Игорь, а твой, вордовский макрос, делает около минуты, но то же четко.

Теперь моя в-карта заработает в Mac OS!!

[IgorGO]

их не только я нашел
вот это

txt = Replace(txt, Chr(10), "")

что делает?

[EducatedFool]

Сообщение от valerij

Теперь моя в-карта заработает в Mac OS!!

Ну ты и крут, Валера
Не думал, что ты вручную переписываешь (и правишь код в текстовом редакторе) videobios для видеокарт...

Честно говоря, пробелы в бинарном файле смотрятся несколько дико, но раз уж надо...

[Sasha_Smirnov]

Sub Sandwich()
'находит в документе восьмёрки 16-ричных цифр и разделяет их пробелами'
Const spacer = " "      'разделитель групп цифр (здесь - пробел)'

Selection.HomeKey wdStory

With Selection.Find
    .Text = "([0-9A-Fa-f]{8})"              'очередные 8 шестнадцатеричных цифр'
    .MatchWildcards = True                  'отмечен флажок Подстановочные знаки'
    .Replacement.Text = "\1" & spacer   'добавляем spacer к группе из 8 цифр'
    .Wrap = wdFindContinue                  'переходим (после добавления) к очередной группе'
    .Execute Replace:=wdReplaceAll  'выполнение замены'
    
    .Text = ""                               'очистка поля Найти:'
    .Replacement.Text = ""          'очистка поля Заменить на:'
    .MatchWildcards = False         'сброс флажка Подстановочные знаки'
    .Execute                                  'выполнение очистки'
End With
End Sub