Почему при прогоне через дебаггер получаю другой результат

[slyscrat]

Есть программа в двух модулях, обрабатывающая far функция находится во втором модуле. При прогоне через CV в DosBox возвращается обработанная строка (A7654321), если же просто запустить .exe то получаю строку с нулями. Что нужно исправить, дабы без дебаггера получать ожидаемый результат? Модули и листинг прилагаются. Заранее спасибо за помощь

[FPaul]

Если работаете в DOS - то у вас будут 16-разрядные адреса.
Т.е. нет и не будет

lea eax, result

возможно ТОЛЬКО

lea ax, result

Нет pushad, есть pusha. Нет 32-разрядных регистров, есть только 16-разрядные. И так далее.
Т.е. всё нужно переписать.

[Black Fregat]

Сообщение от FPaul

Нет 32-разрядных регистров, есть только 16-разрядные.

Вы, простите Turbo Debugger под DOS давно открывали?

[FPaul]

Black Fregat, хорошо - вы меня уели...

Дальше что? Вы помогли этим топикстартеру? Или, всё же, помощь ему состоит в объяснении, что в коде смешался 16 и 32 разрядный код и всё нужно переписать?

Если я не прав - подскажите ТС'у строку с ошибкой, как её исправить. А я вместе с ТС поучусь у вас.

[FPaul]

После исправления смешения разрядности кода получается

.MODEL	small
extrn dwordToStr:far

_STACK SEGMENT PARA STACK 'stack'
 	DB 100h DUP(?)
_STACK ENDS

mPrintString macro string:REQ
	mov 	ah, 09h
	mov 	dx,OFFSET string
	int 	21h
endm

DATA SEGMENT PARA PUBLIC 'data'
	source 	dd 0A7654321h
	result 	db 9 dup ('$')
	template db '0123456789ABCDEF'
DATA ENDS

CODE SEGMENT PARA PUBLIC 'code'
	ASSUME CS: CODE, DS: DATA, SS: _STACK

.386
START:
		MOV	AX, DATA
		MOV	DS, AX
		MOV	ES, AX

		mov	ax, seg [template]
		push	ax
		lea	ax, [template]
		push 	ax
		mov	ax, seg [result]
		push	ax
		lea 	ax, [result]
		push	ax
		mov	ax, seg [source]
		push	ax
		lea	ax, [source]
		push	ax

		call 	dwordToStr
		add	sp,	12

		mPrintString result

		MOV		AX, 4C00h				; the exit fuction  [4C+no error (00)]
		INT		21h						; call DOS interrupt 21h
		CODE ENDS
END START

PUBLIC dwordToStr

CODE1 SEGMENT
	  ASSUME CS:CODE1
.386

dwordToStr proc far
	;кадр стека
	push	bp		;+18
	mov 	bp, sp
	;сохранение используемых регистров
	pusha			;+16=+34
	push	ds
	push	es		;+38

	lds	si, [bp+6]	; ptr source
	les 	di, [bp+10]	; ptr result
	add	di,	2*4-1	; запись в строку с конца
	mov	cx,	4
ForEachByte:
	; считываем очередной байт
	mov	al, [si]
	inc	si
	; загружаем адрес таблицы преобразований
	mov	dx, ds		;сохраняем ds
        lds     bx, [bp+14]
	;преобразования нибблов
        mov     ah, al
        and     al, 0fh
        xlat
        mov     es:[di], al
	dec	di

        mov     al, ah
	shr	al, 4
        and     al, 0fh
        xlat
        mov     es:[di], al
	dec	di

	mov	ds, dx		; восстанавливаем ds
loop	ForEachByte

	pop	es
	pop	ds
	popa
	pop	bp
ret
dwordToStr endp

CODE1 ENDS

END

Передача параметров в процедуру через дальние указатели (сегмент и смещение). Можно обойтись и смещением, но тогда слегка изменить вызов и взятие адресов в процедуре.