Столбцы в обратном порядке

[Арианна]

Здравствуйте. Вот, есть у меня такое зданьице: Дана матрица A2:F10(9x6) , состоящая из целых чисел.Написать макрос, формирующий матрицу в ячейках I2:N10 из заданной путём перестановки столбцов первого с последним, второго с предпоследним и т.д (столбцы в обратном порядке).Исходная матрица должна содержать одинаковые значения в одном столбце. Над матрицами должны быть надписи: Исходная матрица, результирующая матрица. Исходная матрица должна содержать одинаковые значения в одном столбце. Макрос должен вызываться кнопкой с надписью Расчёт. Выполнить нужно через разные виды циклов.
Начала писать For Next, но что-то он не работает... Причем не находит никаких ошибок, а просто не считает. Подскажите, пожалуйста, в чем дело.

Sub Расчет()
Dim col, j, a, rw As Integer
rw = 2
a = 13
For col = 1 To 10
j = col + a
Worksheets("Лист1").Range(Cells(2, j), Cells(6, j)).Value = Worksheets("Лист1").Range(Cells(2, col), Cells(6, col))
a = a - 1
Next col
End Sub

[doober]

Писал на коленке,должно работать

Function REVERS(X As Variant) As Variant
    Dim r As Integer, c As Integer, Y As Variant
    r = UBound(X, 1)
    c = UBound(X, 2)
    ReDim Y(1 To r, 1 To c)
    For n = 1 To r
        For m = 1 To c
            Y(n, m) = X(n, c - m + 1)
        Next
    Next
    REVERS = Y
End Function
Sub Start()
    r = 9
    c = 6
    ReDim X(1 To r, 1 To c)
    For n = 1 To r
        For m = 1 To c
            X(n, m) = m
        Next
    Next
    Y = REVERS(X)
    Range("A2").Resize(9, 6) = X
    Range("I2").Resize(9, 6) = Y

End Sub

[Арианна]

А без функции никак не обойтись?

[doober]

Можно,объедините обе процедуры в одну

[Арианна]

Просто, может есть варианты попроще? На основе этого цикла мне еще три таких делать...

[SAS888]

Можно существенно проще:

Sub Revers()
    Dim i As Integer, a(): a = [A2:F10].Value
    For i = 1 To UBound(a, 2)
        Cells(2, 15 - i).Resize(UBound(a, 1)).Value = Application.Index(a, 0, i)
    Next
End Sub