Макрос поиска текста на листе

[Movled]

Всем доброго времени суток!
Посмотрел по форуму, но не нашел решения своей задачи.
Мне нужно написать макрос, который ищет текст из буфера на листе, который может встретиться не однократно, а найдя его, выбирает последнюю найденную ячейку.
Попробовал в автоматическом режиме, но сам момент поиска из макроса вылетает.
Помогите, пожалуйста

[Movled]

Немного конкретизирую задачу.
Есть таблица с 2-мя листами "все" и "запчасти". Нужно по номеру запчасти из столбца 2 листа "запчасти", найти её на листе "все", причем если их несколько, то последнюю. Взять цену за единицу из листа "все" и прописать её в столбце справа от цены этой запчасти на листе "запчасти".
Я попробовал это сделать автоматически, но получил только вот это:

Sub Макрос1()
'
' Макрос1 Макрос
'
' Сочетание клавиш: Ctrl+й
'
Selection.Copy
Sheets("все").Select
ActiveCell.Offset(-15, -3).Range("A1").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("запчасти").Select
ActiveCell.Offset(0, 8).Range("A1").Select
ActiveSheet.Paste
ActiveCell.Offset(1, -8).Range("A1").Select
End Sub

Тут явно не хватает самого поиска. Умом понимаю, что это просто, но найти нигде не могу.
Подскажите, пожалуйста!

[EugeneS]

можно, например, так, см. вложение

Нажмите кнопку "Выполнить"

[Movled]

Только вот почему-то при переносе макроса из примера в рабочую книгу он начинает некорректно работать
Но, по крайней мере, задано направление мысли, добью вечером

[Hugo121]

Вроде ошибка есть, проверьте, надо +2 добавить:
Range([j2], Cells(UBound(spairparts)+2, "j")).Value = WorksheetFunction.Index(spairparts, 0, 10)

P.S. Там чуть иначе надо, UsedRange всё портит, короче есть ошибки в конце диапазона, надо доработать.

[Movled]

Спасибо, буду разбираться!

[Movled]

Долго разбирался в программе, в большей степени по причине отсутствия нормального справочника, но всё-таки её добил
Выкладываю то, что получилось в итоге

[SAS888]

Можно гораздо проще:

Private Sub findProg()
    Dim i As Long, x As Range: Application.ScreenUpdating = False
    With Sheets("все")
    For i = 2 To Cells(Rows.Count, 2).End(xlUp).Row
        Set x = .[B:B].Find(Cells(i, 2), .Cells(Rows.Count, 2).End(xlUp).Offset(1), , , , xlPrevious)
        If Not x Is Nothing Then Cells(i, "J") = .Cells(x.Row, "G")
    Next: End With
End Sub

Пример во вложении.

[Movled]

Спасибо, SAS888, красиво! Нет предела совершенству!
Но всё, что делается между For и Next в этом примере для меня далеко от понимания.
Кстати, подскажите, что означает

[B:B]

В примере от EugeneS тоже был операнд в квадратных скобках, но в справке я не нашел, что это. Чем отличается

Range([j2], ...

от

Range("j2", ...

[SAS888]

1. Квадратные скобки компилятор VBA понимает как обращение к ячейке (диапазону). Так, например, вместо Columns("B:B") можно использовать [B:B], вместо Range("A1:D10") использовать [A1:D10] и т.д. Также и для именованных ячеек (диапазонов). Согласитесь, что так просто короче.

2. В справке по VBA Excel очень подробно описан метод Find. Посмотрите. Причем, синтаксис VBA допускает либо простое перечисление параметров через запятую (очередность строго определена), либо указывать имя параметра явно. В первом случае, параметры, используемые по умолчанию можно опустить (пустые значения между запятыми), в последнем случае, их просто не нужно указывать. Так, например, строку кода

Set x = .[B:B].Find(Cells(i, 2), .Cells(Rows.Count, 2).End(xlUp).Offset(1), , , , xlPrevious)

можно записать так:

Set x = .[B:B].Find(what:=Cells(i, 2), after:=.Cells(Rows.Count, 2).End(xlUp).Offset(1), SearchDirection:=xlPrevious)

Смысл таков: ищем в столбце "B" листа, определенного методом With значение Cells(i, 2), начиная с ячейки .Cells(Rows.Count, 2).End(xlUp).Offset(1), т.е. с ячейки после последней заполненной в этом столбце. Параметр xlPrevious говорит о том, что икать нужно предыдущую ячейку. Строка If Not x Is Nothing Then... значит, что выполнять, если нашлось совпадение. Еще раз повторяю: почитайте про метод Find. У него еще много параметров, которые Вам могут пригодится в дальнейшем.

3. И еще. Обратите внимание, что макросу присвоен статус Private. Это для того, чтобы имя макроса не было видно в списке макросов. Во-первых, это ни к чему, во-вторых, т.к. макрос запускается по нажатию кнопки, то в это время, естественно, активным является лист с кнопкой, поэтому, прописывать в коде активацию листа не потребуется, в-третьих, т.к. макроса нет в списке, его невозможно запустить при другом активном листе. Важно: для того, чтобы макрос, имеющий статус Private был доступен из другого модуля (в нашем случае, из модуля листа), в коде вызова макроса используется метод Run. Т.е. если записать

Private Sub CommandButton1_Click(): findProg: End Sub

и при этом макрос findProg имеет статус Private, то будет ошибка. а если использовать

Private Sub CommandButton1_Click(): Run "findProg": End Sub

то все будет ОК.

Пользуйтесь help-ом по VBA, имеющимся в Excel. Желаю удачи.