помогите найти ошибку

[rUs_LAN]

вот kод

Private Sub CommandButton1_Click()
Dim dirvar As String
browse.Text = GetFolderPath("Виберіть папку", "d:\")
Do While Dir(browse.Text) <> ""
  List.AddItem Dir(browse.Text)
  Loop
End Sub

Function GetFolderPath(Optional ByVal Title As String = "Виберіть папку", Optional ByVal InitialPath As String = "c:\") As String
    GetFolderPath = "": PS = Application.PathSeparator
    With Application.FileDialog(msoFileDialogFolderPicker)
        .ButtonName = "Выбрати": .Title = Title: .InitialFileName = InitialPath
        If .Show = -1 Then GetFolderPath = .SelectedItems(1): If Not Right$(GetFolderPath, 1) = PS Then GetFolderPath = GetFolderPath & PS
    End With
End Function

P.S. спасибо EducatedFool за функцию

[EducatedFool]

Private Sub CommandButton1_Click()
    Dim dirvar As String
    browse.Text = GetFolderPath("Виберіть папку", "d:\")
    If browse.Text = "" Then Exit Sub ' если пользователь отказался от выбора папки
    res = Dir(browse.Text)
     While res <> ""
        List.AddItem res
        res = Dir
    Wend
End Sub

Первый раз функция Dir вызывается с параметром (путём к папке), а потом - без параметра (до тех пор, пока она не вернёт пустое значение)

[rUs_LAN]

спасибо!!!
но почему работает без обявления переменной res?

[rUs_LAN]

и подскажите пожалуйста как сделать маску я делал так но ничево не поличилось

If InStr(Len(browse.Text) - 4, browse.Text, "xlsm", vbTextCompare) Then List.AddItem res

[EducatedFool]

Option Compare Text

Private Sub CommandButton1_Click()
    MyDir = GetFolderPath("Виберіть папку", "d:\")
    If MyDir = "" Then Exit Sub ' если пользователь отказался от выбора папки
    res = Dir(MyDir): browse.Text = MyDir
     While res <> ""
        If res Like "*.xls*" Then List.AddItem res
        'или, например, так
        'If Right(res, 5) = ".xlsm" Then List.AddItem res
        res = Dir
    Wend
End Sub

но почему работает без обявления переменной res?

Объявлять переменные желательно, но не обязательно.
VBA автоматически преобразует тип переменной (в данном случае из присвоенного по умолчанию типа Variant в тип String)
Про это написаны сотни статей, лучше обратитесь к ним за консультацией по этому вопросу...

[rUs_LAN]

спасибо!!! ви мне очень помогли