Связь на конкретном листе

[Роня]

Уважаемые программисты!
Помогите мне, пожалуйста!

arlinks = ThisWorkbook.LinkSources
For i = 1 To UBound(arlinks)
ThisWorkbook.ActiveSheet.Cells(i, 15).Value = arlinks(i)
Next i

Метод LinkSources выводит все имеющиеся в книге связи.
А мне нужно узнать, какая связь (она должна быть только одна) имеется на конкретном листе. Можно ли это сделать?
Или хотя бы можно как-то вытащить текст, который пишется в f(x)?

Спасибо, надеюсь на ответ!

[pashulka]

Private Sub FindLink()
    Dim iLinkCell As Range
    Set iLinkCell = ThisWorkbook.Worksheets(1).UsedRange.Find _
    (What:="=*[*]*", LookIn:=xlFormulas, LookAt:=xlPart)

    If Not iLinkCell Is Nothing Then
       MsgBox "Ячейка : " & iLinkCell.Address & _
       " предположительно содержит внешнюю ссылку", , ""
       'Если необходимо найти все подобные ячейки, то
       'воспользуйтесь методом FindNext (пример есть в справке)
    End If
End Sub

[Роня]

Pashulka, спасибо за ответ!
я не совсем понятно сначала написала, но мне нужно выцепить саму формулу (а еще лучше наименование файла, с которым имеется связь,) в конкретной ячейке конкретного листа.
попробовала использовать
s = Application.WorksheetFunction.Find( "ффф", "F9")
но выдается ошибка "Application-defined or object-defined error"
Помогите, пожалуйста, еще

[pashulka]

Роня, Вы можете использовать что-то вроде нижеопубликованного кода, или перебрать внешние ссылки и поискать их в формуле.

Private Sub GetLink()
    With ThisWorkbook.Worksheets(1).Range("A1")
         If Not .FormulaHidden Or Not .Parent.ProtectContents Then
            iFormula$ = .Formula
            'Если нет уверенности в том, что ячейка содержит
            'формулу, то проверить её наличие можно использовав
            'свойство HasFormula
            If iFormula$ Like "=*[*.XLS]*" Then
               iMin% = InStr(iFormula$, "[") + 1
               iMax% = InStr(iFormula$, "]")
               iFileName$ = Mid(iFormula$, iMin%, iMax% - iMin%)
               MsgBox iFileName$, , ""
            End If
         Else
            MsgBox "Формула скрыта от глаз любопытствующих", , ""
         End If
    End With
End Sub

[Роня]

Pashulka, все получилось, спасибо!!!