Как в Notepad++ строки поменять местами

[satfan]

Как в Notepad++ выделить все нужные строки и переместить их выше на 1 строку. Выделяем все строки начинающиеся: #DESCRIPTION Есть исходный файл:

#EXTM3U
http://strm.yandex.ru/kal/1hd/1hd0_169_480p.json/index-v1-a1.m3u8:1HD
#DESCRIPTION 1HD
http://rtmp.one.by:1300:1 муз HD
#DESCRIPTION 1 муз HD
http://rtmp.one.by:2300:Первый Музыкальный RU BY HD
#DESCRIPTION Первый Музыкальный RU BY HD
http://live.stranafm.cdnvideo.ru/stranafm/stranafm_hd.sdp/playlist.m3u8:Страна FM TV
#DESCRIPTION Страна FM TV
http://rtmp.one.by:1300:One.by HD
#DESCRIPTION One.by HD
http://stream.mediawork.cz/retrotv//retrotvHQ1/playlist.m3u8:Retro Music TV
#DESCRIPTION Retro Music TV

Все помеченные строки начинающиеся: #DESCRIPTION Нужно сместить на 1 строку вверх.
То есть строки: #DESCRIPTION и строку http:
Поменять местами.
В результате должно быть так:

#EXTM3U
#DESCRIPTION 1HD
http://strm.yandex.ru/kal/1hd/1hd0_169_480p.json/index-v1-a1.m3u8:1HD
#DESCRIPTION 1 муз HD
http://rtmp.one.by:1300:1 муз HD
#DESCRIPTION Первый Музыкальный RU BY HD
http://rtmp.one.by:2300:Первый Музыкальный RU BY HD
#DESCRIPTION Страна FM TV
http://live.stranafm.cdnvideo.ru/stranafm/stranafm_hd.sdp/playlist.m3u8:Страна FM TV
#DESCRIPTION One.by HD
http://rtmp.one.by:1300:One.by HD
#DESCRIPTION Retro Music TV
http://stream.mediawork.cz/retrotv//retrotvHQ1/playlist.m3u8:Retro Music TV

Строк много.

[Black Fregat]

Надо играться с заменой через регулярки. Конкретнее прямо сейчас написать не могу - нет под рукой Notepad++

[Desc]

Сообщение от Black Fregat

Надо играться с заменой через регулярки.

Как по мне, ручками там нужно баловаться
Только вот ТС видимо ленится, вдруг цудо прилетит.

[ViktorR]

Вот, побаловался с Командной строкой:

@echo off
chcp 1251 > nul
if -"%1"==-"/a" (goto :Avtor)
if -"%1"==-"/?" (goto :Help)
if -"%1"==-"" (goto :Help)
if NOT exist %1 (goto :Err)
if -"%2"==-"" (goto :Help)
if -"%3"==-"" (
   set N=0
) else (
   set N=%3
)
rem === Main =============
if exist %2 (del %2)
set str1=
set str2=
set flag=AB
SETLOCAL ENABLEDELAYEDEXPANSION
for /f "TOKENS=*" %%a in (%1) do (
   if +!N! GTR +0 (
      echo %%a >> %2
      set /a N=N-1
   ) else (
      if -!flag!==-AB (
         set str1=%%a
         set flag=BA
      ) else (
         echo %%a >> %2
         echo !str1! >> %2
         set flag=AB
      )
   )
)
goto :EOF
rem
rem =========================
:Err
echo.
echo Err. %1 - файл должнен существовать.
rem =========================
:Help
echo.
echo Вызов: rearrrange.cmd ^<par1^> ^<par2^> [^<par3^>]
echo ^<par1^> - имя входного файла
echo ^<par2^> - имя выходного файла
echo ^<par3^> - число пропускаемых строк (от начала фала)
echo          если этот параметр не задан,
echo          то обработка с первой строки
echo или: change.cmd /a ^| /?
echo где /? - Справка
echo     /a - Автор
echo.
echo Скрипт:
echo 1. Пропускает заданное число строк ^<par3^> во входном файле ^<par1^>
echo 2. Переставляет парно остальные строки:
echo   Было: Строка a
echo         Строка b
echo         Строка c
echo         Строка d
echo Станет: Строка b
echo         Строка a
echo         Строка d
echo         Строка c
echo 3. Результат сохраняется в файле ^<par2^>
echo.
exit /b 0
rem =========================
:Avtor
echo.
echo Автор: ViktorR

[Desc]

Таки прилетело цудо